#!/usr/bin/env perl

use strict;
use warnings;

use PPI;
use Text::WordDiff;

if( scalar(@ARGV) != 2 ){ print usage($0) . "\n"; exit(0); }

my ($infile1, $infile2) = @ARGV;

my $doc = PPI::Document->new($infile1);
if( ! defined($doc) ){ print STDERR "$0 : call to ".'PPI::Document->new()'." has failed for input file '$infile2'.\n"; exit(1); }
my (%subs1, %subs2, $asub);
for $asub ( @{ $doc->find('PPI::Statement::Sub') || [] } ) {
	# loop over all subs in file
	unless ( $asub->forward ) {
		# store sub's contents in hash keyed on sub's name
		$subs1{ $asub->name } = $asub->content;
	}
}

$doc = PPI::Document->new($infile2);
if( ! defined($doc) ){ print STDERR "$0 : call to ".'PPI::Document->new()'." has failed for input file '$infile2'.\n"; exit(1); }
for $asub ( @{ $doc->find('PPI::Statement::Sub') || [] } ) {
	# loop over all subs in file
	unless ( $asub->forward ) {
		# store sub's contents in hash keyed on sub's name
		$subs2{ $asub->name } = $asub->content;
	}
}
my ($k, $v1, $v2, $res, $anitem);
my @dont_exist = ();
my %allkeys = map { $_ => 1 } (keys %subs1, keys %subs2);
foreach $k (sort keys %allkeys){
	if( ! defined($v1=$subs1{$k}) ){
		push(@dont_exist, "$k : Does not exist in '$infile1'\n");
		next
	} elsif( ! defined($v2=$subs2{$k}) ){
		push(@dont_exist, "$k : Does not exist in '$infile2'\n");
		next
	}

	# sub (same name) exists in both files, diff sub's contents in files:
	$res = Text::WordDiff::word_diff(
		\$v1,
		\$v2,
	);
	# print diff results
	print
	  "----- begin '$k' -----\n"
	. $res
	. "\n----- end '$k' ------\n"
	;
}
# and also print the subs which exist in one file but not the other file
print join("", @dont_exist);

exit(0);

sub	usage {
	return "Usage : ".$_[0]." file1 file2\nColor output guide:\n\tRED : file1\n\tGREEN: file2\n"
}