"Wizard" by "Rene Schickbauer"

maximum score is 10;

Section 1 - The Farm

Kansas Prairie is a room. "You are in the middle of the Kansas Prairie. Nothing but grey skies and brown grass to see, expect for Uncle Henry's farm to the east."



Uncle Henry's Farm is east of Kansas Prairie. "The farm looks quite old. Three of the five buildings are already collapsing and the main house is badly in need of a new roof. Only the small shed north of you seems well maintained."

 A plough is fixed in place in Uncle Henry's Farm. "A lonely plough rests in the middle of the yard." The description is " It looks ancient and rusty, and it probably hasn't been moved for ages, since rust stains the ground around it."

Instead of taking the plough, say "I'm not a horse. This is far to heavy to move for a human."

A shed is fixed in place in Uncle Henry's Farm. The description is "This shed serves as the entrance to the storm shelter."

A main house is fixed in place in Uncle Henry's Farm. The description is "This is the main house of the farm. As well serving as squalid living quarters, kitchen and moonshine distillery, it is also the hen house. The roof is rather leaky, but on the plus side, Uncle Henry can grow his psychedelic mushrooms  in the attic."

A haystack is fixed in place in Uncle Henry's Farm. "At the west side of the yard, you see a small haystack." The description is "Rotten as it may look, this hay will be the only source of food for Uncle Henry's two horses this winter."

Instead of taking the haystack, say "Well, i heard of searching for a needle in a haystack. But taking the whole haystack with me seems kind of pointless."
	
Instead of searching the haystack:
	if the needle is in Smurg begin;
		now the player has the needle;
		say "Amazingly, you find a sharp needle in the haystack!";
		award 10 points;
	otherwise;
		say "You spent hours riffling through the haystack. But you find nothing else.";
	end if;


Section 1 - Shed and Shelter

The Inside shed is north of Uncle Henry's Farm. "This is a very *small* shed. There is a door on the south and a ladder leading down to the storm shelter."

The Storm shelter is a room. "This massively build storm shelter will survive any storm! The three meter thick walls of concrete and the massive, sliding steel door make sure of that."

The shelter door is a locked door. The shelter door is down from the Inside shed and up from the Storm shelter. The description is "This is a massive, sliding steel door. It is nearly twenty centimeters thick and damn near unbreakable. There is a keyhole on the left side of the door frame."

Report opening the shelter door:
	if the player is in the Inside shed begin;
		say "You pull with all your might. Slowly, the heavy steel door starts sliding silently into its doorframe." instead;
	otherwise;
		say "You press the red button labeled 'Open door' and the door swishes open, just like the one on Kirk's bridge." instead;
	end if;

Report closing the shelter door:
	if the player is in the Inside shed begin;
		say "You push on the door with all you got. Slowly, the heavy steel door starts closing until it shuts with a mighty bang." instead;
	otherwise;
		say "You press the green 'Close door' button and the door slams shut in less than a second." instead;
	end if;

Understand "lock [something]" as locking keylessly. Locking keylessly is an action applying to one thing.

Check locking keylessly:
	if the noun is open, say "You must close [the noun] first." instead; 
	if the noun is not a door, say "[The noun] is not something you can lock." instead; 
	if the noun is locked, say "[The noun] is already locked." instead; 
	if the player carries the needle and the player is in the Inside shed, try locking the noun with the needle instead; 
	if the player is in the Inside shed, say "You can't lock the door from this side without some sort of key!" instead.
	
Carry out locking keylessly:
	now the noun is locked.
	
Report locking keylessly:
	if the player is in the Inside shed begin;
		say "You fiddle with the needle in the key hole for a few minutes. Then you give up, slam your steel capped boot into the door frame and [the noun] locks with rather pleasing 'clonk'." instead;
	otherwise if the player is in the Storm shelter;
		say "You flip over the deadbolt on [the noun] and it locks with a satisfying 'clunck'.";
	otherwise;
		say "You lock [the noun].";
	end if;
	
Understand "unlock [something]" as unlocking keylessly. Unlocking keylessly is an action applying to one thing.

Check unlocking keylessly: 
	if the noun is not a door, say "[The noun] is not something you can lock." instead; 
	if the noun is unlocked, say "[The noun] is already unlocked." instead; 
	if the player does not carry the needle and the player is in the Inside shed, say "You can't unlock the door from this side without some sort of key!" instead.

Carry out unlocking keylessly: 
	now the noun is unlocked.

Report unlocking keylessly:
	if the player is in the Inside shed begin;
		say "You fiddle with the needle in the key hole. After a few minutes you manage to unlock [the noun]." instead;
	otherwise if the player is in the Storm shelter;
		say "You flip over the deadbolt to unlock [the noun].";
	otherwise;
		say "You unlock [the noun].";
	end if;

Report unlocking:
	if the player is in the Inside shed begin;
		say "You fiddle with the needle in the key hole and unlock [the noun]." instead;
	end if;


Section 998 - Play area limitations

Instead of going nowhere:
	if the player is in Kansas Prairie begin;
		say "The Kansas Prairie is vast and stretches seemingly forever into the horizon. You don't want to get lost!";
	otherwise if the player is in Uncle Henry's Farm;
		say "Uncle Henry told you not to go there!";
	otherwise;
		say "You bump into an invisible wall.";
	end if;
	

Section 999 - Hidden Objects

Smurg is a room.

A needle is in Smurg. It unlocks the shelter door. The description is "A sharp needle. It looks new."