Re: PDF API2 - landscape and rotating text and image

[kcott]

"# does not rotate correctly because I don't quite understand the translate part"

When you rotate the page ($page->rotate(90)) to change from portrait to landscape, the X-Y axes change from horizontal-vertical to vertical-horizontal. The -translate values reference the axes; you need to adjust them for the page rotation change. I suspect this is maybe causing you problems understanding what's going on here: it's neither immediately obvious nor intuitive, so your confusion is unsurprising. I suggest you spend some time playing around with the values to get a feel for this.

The following code generates a landscape-oriented page which roughly looks like this:

+-------------------------+
| Left text    Right text |
|                         |
| +------+     +------+   |
| |  ^^  |     |  ^^  |   |
| |  ||  |     |  ||  |   |
| | img1 |     | img2 |   |
| +------+     +------+   |
+-------------------------+

I used different text and images purely for testing purposes; obviously, you can use the same text and images on both sides. The images were 64x64 pixel PNGs which had a clear UP direction (to check the rotation).

You'll no doubt need to change certain values to suit your layout requirements; however, I hope this gives you a solid starting point.

#!/usr/bin/env perl

use strict;
use warnings;
use autodie;

use PDF::API2;

my $pdf_file = 'test.pdf';
my $left_text = 'This text on the left.';
my $right_text = 'This text on the right.';
my ($left_img, $right_img) = qw{left.png right.png};

my $pdf = PDF::API2::->new(-file => $pdf_file);
my $page = $pdf->page();
$page->mediabox('A4');
$page->rotate(90);

my $font = $pdf->corefont('Helvetica');

my @text_cfg = (
    { text => $left_text, pos =>  [50, 40] },
    { text => $right_text, pos =>  [50, 450] },
);

for my $cfg (@text_cfg) {
    my $text = $page->text();
    $text->font($font, 12);
    $text->transform(
        -translate => $cfg->{pos},
        -rotate => 90,
    );
    $text->text($cfg->{text});
}

my @gfx_cfg = (
    { img => $pdf->image_png($left_img), pos => [150, 40] },
    { img => $pdf->image_png($right_img), pos => [150, 450] },
);

my $gfx = $page->gfx;

for my $cfg (@gfx_cfg) {
    $gfx->save();
    $gfx->transform(
        -translate => $cfg->{pos},
        -rotate => 90,
    );
    $gfx->image($cfg->{img}, 0, 0);
    $gfx->restore();
}

$pdf->save();