http://www.perlmonks.org?node_id=118610


in reply to Merge CIDRs

Looking at this and considering my own post, I thought I would try to improve it. The following code allows trailing zeros to be left off the input CIDR and it will leave off the trailing zeros in the output. It also handles 0/0, which neither of our posts did 

use strict;

sub cidr2bits {
  my $cidr = shift;
  my $n = $cidr =~ s,/(\d+)$, ? $1 : 32;
  my @n = $cidr =~ m,\d+,g;
  substr(unpack("B*",pack("C4", @n,0,0,0,0)),0,$n);
}

sub bits2cidr {
  my $bits = shift;
  my $n = length $bits;
  $bits .= "0" x 8;
  join(".", unpack("C*", pack("B*",($bits =~ /^((?:.{8})+?)0*$/)[0])))
+."/$n";
}

sub mergecidr {
  local $_ = join("\n", sort  map { cidr2bits($_) } @_);
  1 while s/^(\d*)\n\1.*$/$1/mg || s/^(\d*)0\n\1.$/$1/mg;
  map { bits2cidr($_) } (!@_ || length($_)) ? split : '';
}

[download]

Update: Swapped the two s/// in the while to prevent the problem merlyn described. Now in the case of 

10010
100100
100101

[download]

the first two lines will be merged first and yeild the correct result

Replies are listed 'Best First'.
Re: Re: Merge CIDRs
by merlyn (Sage) on Oct 13, 2001 at 05:24 UTC 
    1 while s/^(\d*)0\n\1.$/$1/mg || s/^(\d*)\n\1.*$/$1/mg;

    [download]
    There's a reason I put [1] there instead of your ".". Consider what happens when you have the following: 
    10010
100100
100101

    [download]
    The last two lines will be merged, creating 
    10010
10010

    [download]
    And your code will strip that final 0 from both lines, creating "1001". Wrong. You must ensure that it's a 1. Can't be "any".

    -- Randal L. Schwartz, Perl hacker

[reply]
[d/l]
[select]

In Section Cool Uses for Perl