Re: Producing a list of offsets efficiently

[tlm]

index beats everything else I have tried, including various regexps. The fastest I have found is

  my @o;
  my $o = -1;
  push @o, $o while ($o = index($s, 'a', $o+1)) > -1;

E.g.:

use strict;
use warnings;

use Benchmark 'cmpthese';

srand( 0 );
my $s = join '', map chr(97+int(rand(26))), 1..100_000;

cmpthese( -1,
          {
           windex   => \&windex,
           windex_1 => \&windex_1,
           wregex   => \&wregex,
          }
        );

sub windex {
  my @o;
  my $o = -1;
  while ( ( $o = index( $s, 'a', $o+1 )) > -1 ) { push @o, $o }
  return;
}

sub windex_1 {
  my @o;
  my $o = -1;
  push @o, $o while ($o = index($s, 'a', $o+1)) > -1;
  return;
}

sub wregex {
  my @o;
  $s =~ m/a(?{ push @o, pos() - 1 })(?!)/;
  return;
}
__END__
          Rate   wregex   windex windex_1
wregex   204/s       --     -37%     -39%
windex   324/s      59%       --      -4%
windex_1 336/s      65%       4%       --

Updates: Way too many. Reversed my first reversal (I'd inadvertently introduced a bug in wregex that resulted in only one match taking place, which made it look faster). Minor tweaks to wregex (eliminated the unneccessary /g, and removed a stray 0; in the (?{}) code.