Preventing SQL injection attacks: Placeholders are enough for MySQL, Postgresql and SQLite

[talexb]

This is a followup to my original question Preventing SQL injection attacks: are -T and placeholders not enough?. When I run the following code on my system..

#!/usr/bin/perl -w

use DBI;

#  Test SQL injection attack. The test table 'jobs' was created with
#  the command 'create table jobs (j_id integer, j_value text);' in
#  all three databases.

my @databases = ( 'mysql:test', 'Pg:dbname=test', 'SQLite:test.sq3' );

my @data = (
  { id => 44, value => "Some benign text" },
  { id => 55, value => "Just regular data" },
  { id => 66, value => "Evil data');DELETE FROM jobs;" }
);

{
    foreach my $thisDbName ( @databases ) {

      my $dbh = DBI->connect("DBI:$thisDbName", undef, undef )
        or die "Unable to connect to $thisDbName: " . $DBI::errstr;
      print "Connected OK to $thisDbName.\n";

      #  Clean up test table before we start ..

      my $cmd = "DELETE FROM jobs";
      my $sth = $dbh->prepare($cmd);
      print "Clear out existing data from the test table ..\n";
      $sth->execute or die "Problem executing $cmd: " . $sth->errstr;

      $cmd = "INSERT INTO jobs (j_id, j_value) VALUES (?,?)";
      $sth = $dbh->prepare($cmd);

      #  Add test data into table ..

      foreach my $hashref ( @data ) {

        print "Add "
          ."($hashref->{'id'},$hashref->{'value'})"
          ." to the test table ..\n";
        $sth->execute($hashref->{'id'}, $hashref->{'value'})
          or die "Problem executing $cmd: " . $sth->errstr;
      }

      #  Dump out the resulting tables.

      $cmd = "SELECT * FROM jobs";
      $sth = $dbh->prepare($cmd);
      print "Dump out the result.\n";
      $sth->execute or die "Problem executing $cmd: " . $sth->errstr;

      DBI::dump_results($sth);
      print "\n";
    }
}

I get the following results:

Connected OK to mysql:test.
Clear out existing data from the test table ..
Add (44,Some benign text) to the test table ..
Add (55,Just regular data) to the test table ..
Add (66,Evil data');DELETE FROM jobs;) to the test table ..
Dump out the result.
'44', 'Some benign text'
'55', 'Just regular data'
'66', 'Evil data');DELETE FROM jobs;'
3 rows

Connected OK to Pg:dbname=test.
Clear out existing data from the test table ..
Add (44,Some benign text) to the test table ..
Add (55,Just regular data) to the test table ..
Add (66,Evil data');DELETE FROM jobs;) to the test table ..
Dump out the result.
'44', 'Some benign text'
'55', 'Just regular data'
'66', 'Evil data');DELETE FROM jobs;'
3 rows

Connected OK to SQLite:test.sq3.
Clear out existing data from the test table ..
Add (44,Some benign text) to the test table ..
Add (55,Just regular data) to the test table ..
Add (66,Evil data');DELETE FROM jobs;) to the test table ..
Dump out the result.
44, 'Some benign text'
55, 'Just regular data'
66, 'Evil data');DELETE FROM jobs;'
3 rows

So, as far as I'm concerned, placeholders are enough to prevent SQL injection attacks for MySQL, PostgreSQL and SQLite. If anyone can point out something obvious that I've missed, please let me know.

Update: Thanks to the monks who have contributed, we now have the following results:

Pass	Fail
MySQL, PostgreSQL and SQLite (from this node) Oracle 10g olus MS Access and SQLServer (both 2000, I believe) rhesa IBM UDB version 9.5.0 on Linux 2.6.9 i386 andreas1234567 CSV, DBM -- In theory that means that should pass with any of the SQL::Statement DBDs. jZed DBD::Sybase 1.08, Sybase ASE 15.0.2 and Sybase OpenClient 15 mpeppler	Nothing yet.

Update 2: As per tye's reply below, please note that this is obviously not a rigorous test that proves conclusively that placeholders always prevent SQL injection attacks, but rather a quick check that an obvious test does indeed work properly.