Re^3: 5.24 -> 5.28 -- what has changed in autovivification?

[swl]

The changes file does not list anything obvious to me.

The git repo listed in the module info unfortunately seems not to be accessible.

I'm not sure if it helps shed any light due to the refactoring, but the full set of differences between the two versions can be obtained through metacpan.

https://metacpan.org/diff/file?source=VPIT/autovivification-0.16&target=VPIT/autovivification-0.18

[haukex]

#!/usr/bin/env perl
use warnings;
use strict;
no autovivification qw{fetch store exists delete}; 

my $h = { a => { p => 2, q => 3 } };

print "perl ver $], autoviv ver $autovivification::VERSION:\n"; 
! $$h{a}{x}{z} and print "a/x/z not\n"; 

__END__

perl ver 5.024004, autoviv ver 0.16:
a/x/z not

perl ver 5.028001, autoviv ver 0.16:
a/x/z not

perl ver 5.024004, autoviv ver 0.18:
Can't vivify reference at a.pl line 9.

perl ver 5.028001, autoviv ver 0.18:
Can't vivify reference at a.pl line 9.

[leszekdubiel]

I've found:

The documentation for the exists operator no longer says that autovivification behaviour "may be fixed in a future release". We've determined that we're not going to change the default behaviour. perl #127712

perl #127712

I understand that there are only two options:

• NO autovivification. Then you can't do if (exists $h{a}{b}{c}{d}) { ... }, because you try to dereference non-existent $h{a}{b}, then you get error.
• Or default (*) behaviour, WITH autovivification, that is when you do if (exists $h{a}{b}{c}{d}) { ... }, then perl will gracefully create $h{a}, $h{a}{b}, $h{a}{b}{c} for you :) :)
(*) -- this is the default behaviour that creators of perl decided not to change

I hoped to find solution that doesn't autovifify when existence is checked, so I could just act like this if (exists $h{a}{b}{c}{d}) { ... } and not like this if (exists $h{a} && exists $h{a}{b} && exists $h{a}{b}{c} && exists $h{a}{b}{c}{d}) { ... }

My preferred default behaviour would be to return undef for $h{a}{b}{c}{d} and NOT create $h{a}, $h{a}{b}, $h{a}{b}{c}... This is not possible.

[haukex]

I understand that there are only two options

In core Perl, yes (Update: actually, autovivification isn't even in the core). But choroba showed one possibility, and writing a single-purpose routine isn't difficult either (I've admittedly compacted it a bit):

use warnings;
use strict;

sub dive { my $r = shift;
    $r = ref $r eq 'HASH' && exists $$r{$_} ? $$r{$_} : return for @_;
    return $r }

use Test::More;

my $h = { a => { b => { c => { d => 'e' } } } };

is dive($h, qw/ a         /), $h->{a};
is dive($h, qw/ a b       /), $h->{a}{b};
is dive($h, qw/ a b c     /), $h->{a}{b}{c};
is dive($h, qw/ a b c d   /), 'e';
is dive($h, qw/ a b c d e /), undef;
is dive($h, qw/ a x       /), undef;
is dive($h, qw/ a b x     /), undef;
is dive($h, qw/ a x y     /), undef;
is dive($h, qw/ a b x y   /), undef;
is dive($h, qw/ x         /), undef;
is dive($h, qw/ x y       /), undef;
is dive($h, qw/ x y z     /), undef;

is_deeply $h, { a => { b => { c => { d => 'e' } } } };

done_testing;

Update: Both of the links in your post appear to be broken. I assume you were trying to link to perl5280delta and RT#127712.

[choroba]

> This is not possible.

You've been given a solution by haukex in Re: 5.24 -> 5.28 -- what has changed in autovivification?.

Do you need more details? Here's an example:

#! /usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

use Data::Diver qw{ Dive };
use Data::Dumper;

my $h1 = {};
my $h2 = {a => {b => {c => 42}}};

for my $h ($h1, $h2) {
    say "Found $h->{a}{b}{c}" if Dive($h, qw( a b c ));
}
print Dumper $h1, $h2;

Output:

Found 42
$VAR1 = {};
$VAR2 = {
          'a' => {
                   'b' => {
                            'c' => 42
                          }
                 }
        };