defined defined -- Bug or "Feature"?

[roho]

I just finished tracking down a very elusive bug in my code. The bug was caused by two defined's side by side (a copy/paste error). Perl doesn't object at either compile time or at run time, but two defined's reverses the logic of the expression. In the sample code below the first "if" statement is False (as expected), but the second "if" statement is True because of the two defined's.

I suppose there may be a use case somewhere where the result of one "defined" is fed into another, but my first reaction was that this is a bug. What do other monks think about this? Is this a bug in Perl or a "feature"?

#!/usr/bin/perl
use strict;
use warnings;

my $x;

if (defined $x) {
        print "True\n";
} else {
        print "False\n";
}

if (defined defined $x) {
        print "True\n";
} else {
        print "False\n";
}

[dave_the_m]

defined($x) returns a false, but defined value, so defined(defined($x)) is true.

Dave.

[GrandFather]

You state that like you know it to be the case, but I couldn't see that behavior described in the documentation. Do you know this from the code?

[dave_the_m]

The docs say that it returns a boolean value, i.e. a true or false value. It would be surprising for a false value to also be undefined, as you would get 'undefined' warnings if you tried using operators on the results. This shouldn't warn:

$x = defined($y) ^ defined($z);

Dave.

[Anonymous Monk]

I guess he didn't (guess). It's easily tested...

print defined( undef ) // 'n/a';

print defined( undef ) || 'n/a';
n/a

[GrandFather]

The most likely answer is that defined returns an empty string as a false value. An empty string is defined so the left most defined sees a defined value - the result from the right most defined.

So, not really a bug, just an interesting edge case.

[Anonymous Monk]

Probably not, Pl_sv_false ought to be same as undef, there were some bugs regarding this, but i'm afk & my mem is fuzzy. Devel::Peek...:)

[dave_the_m]

PL_sv_undef, PL_sv_no and PL_sv_yes are three distinct values with distinct properties. Only PL_sv_undef is undef.

Dave.

[dsheroh]

two defined's reverses the logic of the expression

No, it doesn't reverse the logic. It's always true, regardless of the single defined's result:

$ perl -E 'say ((defined $x) ? "defined" : "undef")' 
undef
$ perl -E 'say ((defined defined $x) ? "defined" : "undef")'
defined
$ perl -E '$x = 1; say ((defined $x) ? "defined" : "undef")'
defined
$ perl -E '$x = 1; say ((defined defined $x) ? "defined" : "undef")'
defined

This is because, as stated in previous comments, the first (rightmost) defined will always return a defined result, so the second (leftmost) defined always receives a defined input value.

[Anonymous Monk]

perlsyn:

Truth and Falsehood

The number 0, the strings '0' and "" , the empty list (), and undef are all false in a boolean context. All other values are true. Negation of a true value by ! or not returns a special false value. When evaluated as a string it is treated as "", but as a number, it is treated as 0. Most Perl operators that return true or false behave this way.

I'm assuming this is the missing piece of documentation that explains why defined always returns a defined value.