Joining array into new string

[kris1511]

I have array in format

my @groups = [ [ 23 ], [ 22 ] ]; 
my $perms = join ',', @groups;
print Dumper $perms;

It gives me result as array : $VAR1 = 'ARRAY(0x7f82c3792848)';

How can I flatten this kind of array into string. Thanks!!

[poj]

#!perl
use strict;
use Data::Dumper;

#my @groups = [ [ 23,24,25 ], [ 22,21,20 ] ];
# change      ^                            ^

my @groups = ( [ 23,24,25 ], [ 22,21,20 ] ); 
my $perms = join ',', 
            map { join ',', @$_ } @groups  ;
print Dumper $perms;

poj

[stevieb]

++, but please explain the actual problem. Pointers are fine (I use them all the time), but denote them with an explanation of what you mean in human terms.

Even if OP gets the point (no pun intended), others reading this may not.

[nysus]

To be fair to poj, The question he originally asked is "how can I" not "why doesn't it work?"

For the benefit of others: The OP created an outer anonymous array containing two other inner anonymous arrays by using the square brackets. From the @groups array perspective, it only contains a single element, the outer anonymous array. It doesn't "see" the other anonymous arrays inside of it. When you try to join on an array with a single element, you just get the single element returned because there's nothing really to join. The ARRAY(0x...) you see is the string that perl spits out when you print an anonymous array. It represents the location of the array in the computer's memory (I think Perl's virtual machine's memory, to be more precise).

[karlgoethebier]

"Pointers are fine (I use them all the time)" (probably by B.B. King)

I don't see any pointers here. See also "...a reference is often erroneously confused with a pointer or address, and is said to "point to" the data..." as well as the Pointer Sisters.

Best regards, Karl

[tybalt89]

#!/usr/bin/perl

# https://perlmonks.org/?node_id=1222668

use strict;
use warnings;

sub flatten { map ref($_) ? flatten(@$_) : $_, @_ }

my @groups = [ [ 23 ], [ 22 ] ];   # note, single item array :)

my $perms = join ',', flatten(@groups);
print "$perms\n";

# more complex example

@groups = ( [ 20, 21, [22, 23], 24], [ [ 25 ], [ [ [ 26 ] ] ] ], 27 );
$perms = join ',', flatten(@groups);
print "$perms\n";

Outputs:

23,22
20,21,22,23,24,25,26,27

[AnomalousMonk]

See Perl Data Structures Cookbook (perldsc) and perhaps also perllol.