How do I print an array with commas separating each element?

[Anonymous Monk]

How do I print an array with commas separating each element?

Originally posted as a Categorized Question.

[Jouke]

There is:


print join( ',', @array );

[ar0n]

  $, = ',';
  print @array;

$, is the output field separator: print will insert whatever string has been assigned to $, between all of its arguments.

Note that if you use this technique, you should make your assignment to $, temporary by doing

  local $, = ',';

[davorg]

or...

$" = ', ';
print "@array";

--
<http://www.dave.org.uk>

European Perl Conference - Sept 22/24 2000, ICA, London
<http://www.yapc.org/Europe/>

[OfficeLinebacker]

Observe the difference in effects between $" and $, —

$\ = "\n";
my @a = qw( One Two Three );
{
  local $, = ',';
  print @a;
  print "@a";
}
{
  local $" = ',';
  print @a;
  print "@a";
}

Output:

One,Two,Three
One Two Three
OneTwoThree
One,Two,Three

[Roy Johnson]

$" can also be used for this:

  local $" = ',';
  print "@arr\n";

[QM]

[nite_man]

And another way:


map { print $_ . ($_ == $array[$#array] ? '' : ', ' ) } @array;

[Coruscate]

For completeness, here's a verbose solution:

my $x;
my @a = qw(one two three);
print "$a[$_-1], " while $x++ < $#a;
print "$a[$#a]";

[extremely]

Grr., I'd forgotten you can't reply to answers and have it be visible on the answer screen... Plus, this is only a mild (much shorter, tho) variation of another answer. *sigh* We're doing ridiculous ways now? Then why not do this?

my $x;
my @a = qw(one two three);
print $_, ++$x<@a ? ", " : "\n" foreach @a;

For bonus fun, you can crush all syntactical whitespace out of that print line, too.

Still, I'm thinking I'll stick with the built-in join() for future projects...

--
$you = new YOU;
honk() if $you->love(perl)

[turnstep]

Here's another way:

  my $x = 0;
  printf "$array[$x-1]%s",
    $x <= $#array ? "," : "\n"
      while $array[$x++];

It puts a newline instead of a comma after the last element.

[Nooks]

Re: How do I print an array with commas seperating each element?

Originally posted as a Categorized Answer.

[Nooks]

Re: How do I print an array with commas seperating each element?

Originally posted as a Categorized Answer.

[hazem]

I don't understand how this works?

How does this work?

 
<p> local $, = ','; </p>
<p> local $" = ',';</p>

 
sub printSpecial() {
      $\ = "\n";
      my @a = qw( One Two Three );

      print ("\n");
      print ("Join print statement\n");
      print ("\n");
      print join( ',', @a );

      {
        # $, The output field separator for the print operator.
        local $, = ',';
        print @a;
        print "@a";
      }
      {
        print ("\n");
        local $" = ',';
        print @a;
        print "@a";

      }
}

Originally posted as a Categorized Answer.