XML::LibXML findnodes fails when using namespaces

[jeteve]

Hi fellow monks.

I'm using XML::LibXML to edit xml files but I'm stucked to this problem:

When the root element of my document has an xmlns attributes, the findnodes method fails to give me the node I want.

Here is a test code:

use XML::LibXML ;

my $xml = q{<?xml version="1.0" encoding="iso-8859-1"?>
<Tag1 xmlns="wow">
  <Foo>content</Foo>
</Tag1>
};

my $xml2 = q{<?xml version="1.0" encoding="iso-8859-1"?>
<Tag1>
  <Foo>content</Foo>
</Tag1>
};

my $parser =  XML::LibXML->new();
my $doc1 = $parser->parse_string($xml);
my ($foo) = $doc1->findnodes('/Tag1/Foo');

print "Foo in xml: ".$foo."\n"; ## Gives undef (with xmlns)

my $doc2 = $parser->parse_string($xml2);
my ($foo2) = $doc2->findnodes('/Tag1/Foo'); ## IS OK (without xmlns)
print "Foo in xml2: ".$foo2->textContent()."\n" ;

Can anybody help ? I searched how to make the parser namespace negligent but I didn't find. Thanks . J.

[gellyfish]

You need to register the namespace, this is made easy with XML::LibXML::XPathContext:

use XML::LibXML;
use XML::LibXML::XPathContext;
                                                                      
+          
my $xml = q{<?xml version="1.0" encoding="iso-8859-1"?>
<Tag1 xmlns="urn:wow">
  <Foo>content</Foo>
</Tag1>
};
                                                                      
+                                                                     
+                    
                                                                      
+          
my $doc = XML::LibXML->new->parse_string($xml);
my $xc = XML::LibXML::XPathContext->new($doc);
$xc->registerNs('foo', 'urn:wow');
                                                                      
+          
my ($foo) = $xc->findnodes('//foo:Tag1/foo:Foo');
                                                                      
+          
print "Foo in xml: ".$foo->textContent()."\n";

You can register any arbitrary prefix to your namespace URI to use in your XPath expression but note I have changed your namespace to an absolute URI as you get an error from XML::LibXML otherwise.

/J\

[tomhukins]

gellyfish has already answered your question, but you might also find some of the answers given to XML::LibXML and XML Namespaces (processing OpenOffice documents) helpful.