Is there a better way to get all the t/.t test files an array?

[tphyahoo]

Salutations, brother monks.

I have just started using Test::Harness, love it. The first thing you have to do, it appears, is push all your test files onto an array so you can runtests(). Rather than do this manually, I am grabbing all the files that end with .t in a directory, using File::Find.

This works, but it seemed rather long. Is there is a more elegant/shorter way to accomplish the same thing?

use strict;
use Test::Harness;
use File::Find;

my @tests;

my @test_files = get_files('./t');

push @tests, @test_files;
runtests(@tests);

sub get_files {
    my $directory = shift;    
    opendir (DIR, $directory) or die "couldn't open directory: $direct
+ory";
    
    my @myfiles;
    my @directories_to_search = ("$directory");
    
    find( sub { 
        my $name = $File::Find::name;
        if ( $name =~ /\.t$/i ) {
            $name =~ s|\\|/|; # substitute forward slash for back slas
+hes, icky but don't know a better way.
            #print "name: $name\n";
            push @myfiles, $name;
        } 
    }, @directories_to_search);
    return @myfiles;
}

Update: followup at Re: Testing for Beginners

[davido]

To simply grab a list of filenames that match some expression within a directory, just use glob:

sub get_files {
    chdir( $_[0] );
    return glob( $_[1] );
}

Usage:

my( @files ) = get_files( '/path/to/files', '*.t' );

This will change your current working directory.

[revdiablo]

If you don't need a recursive search, davido's idea to use glob is preferable. If you do, however, File::Find is a fine solution. Your sub can be cleaned up a bit, though:

sub get_files {
    my $directory = shift;    
    
    my @files;
    
    find(sub { 
        return unless /\.t$/;

        my $n = $File::Find::name;
        $n =~ tr{\\}{/};
        push @files, $n;
    }, $directory);

    return @files;
}

[donarb]

You can also test your code within a module directory. Then you can let Perl's make system find all of your .t files for you and test with a simple 'make test' on the command line.

[tphyahoo]

Sounds promising, but I don't really understand. Could you link to the relevant information describing how to do this? I use modules, but I am not familiar with the MakeMaker / Module::Build type infrastructure for distribution. (High on the list of things to learn.)

[adrianh]

Untested:

use Test::Harness;
use File::Find::Rule;
runtests( File::Find::Rule->file->name('*.t')->in('./t'));

On the off chance that you're considering creating a command line tool for running test scripts, you might want to look at prove (part of recent Test::Harness distributions) and Test::Verbose.