pick a word contaning reg-ex

[keesturam]

Hello Monks, I have started learning perl and was trying to do some exercise in regular expressions. One of the exercise was this.. "Construct regular expressions which can pick out words from a file with the Words containing an exclamation mark" I can write a pgm to find if there is an exclamation in a line/file. But how do I extract the word containing a reg ex (exclamation as in this case)? I tried googling, but couldn't find a suitable answer. --Karthick

[2teez]

You mean something like this:

use warnings;
use strict;


while(<DATA>){
  chomp;
    print grep{/.+?\!/} split
}


__DATA__
 Mary had a little lamb! ,
 whose fleece! was white! as snow.

 And everywhere! that Mary went,
 the lamb was sure! to go.

[Kenosis]

And another option:

use Modern::Perl;

while (<DATA>) {
    say $1 while /(\S+!)/g;
}

__DATA__
Mary had a little lamb! ,
whose fleece! was white! as snow.

And everywhere! that Mary went,
the lamb was sure! to go.

Output:

lamb!
fleece!
white!
everywhere!
sure!

[Wiggins]

The problem says "Words containing an exclamation mark". This is not the same as "ending with".

  /(\w*!\w*)/

This is flawed because it matches "!".
I don't know how to specify at least 1 sub-part must have a length > 0.

[Lotus1]

#!/perl
use warnings;
use strict;

while(<DATA>){
    print map {"$_\n"} grep{/!/ and /[^!]/} split;
}

__DATA__
 Mary had a little lamb! ,
 whose fleece! was white! as snow.

 And everywhere! that Mary went,
 the lamb was sure! to go.

oops!eedaisy
! ! !! HI!!IH

[keesturam]

Oh.! Reply from previous post answers my question as well!!

perl -ne '/(\w*!\w*)/g && print "$1\n";' code_file(s)

Lesson learnt. search for existing threads before posting questions :-)

[space_monk]

(...Presuming you mean: Re: extracting words with certain characters)

C'est rien! :-)

[Lotus1]

I just tried the code above and it only prints the first word (update: on each line) that contains an exclamation point.

#!/perl
use warnings;
use strict;

while(<DATA>){
    #print map {"$_\n"} grep{/!/} split;
    /(\w*!\w*)/g && print "$1\n";
}

__DATA__
 Mary had a little lamb! ,
 whose fleece! was white! as snow.

 And everywhere! that Mary went,
 the lamb was sure! to go.

oops!eedaisy

Produces this:

lamb!
fleece!
everywhere!
sure!
oops!eedaisy

[sundialsvc4]

There are several things that you should, yourself, search for answers to.   First, how to write a regular expression that searches for “one-or-more Word characters followed by an exclamation mark.”   Then, the meaning of the idea “greedy,” and how to specify it.   Finally, how to perform more than one regular-expression match (in a loop ...) within a single string.

The information is there e.g. in perldoc perlre.   If patiently read from stem to stern.

[keesturam]

Thanks..!! This was really helpful.