Re: Efficient bit counting with a twist.

[trizen]

my $c = unpack("%32b*", pack "B$p", unpack "B$p", $v);

Note that $p start with zero.

[BrowserUk]

Note that that sequence of unpack/pack/unpack achieves exactly the same thing as AnomalousMonk's unpack "%32b$p".

But the latter avoids turning a 500MB string into a 4 billion element list of 1s and 0s before converting it back to the 500MB string; which is what that sequence of unpack/pack/unpack does.

[Anonymous Monk]

Maybe I'm crazy, but this doesn't seem to work:

#!/usr/bin/perl

use strict;
use warnings;

my $mask = hex($ARGV[0]);

my $setbits = unpack("%32b*", $mask);

printf("0x%x has %d set\n", $mask, $setbits);

Then I run it:
./bittest 0xff
0xff has 11 set

Or worse:
./bittest 0x1001
0x1001 has 14 set

Even the simple case:
./bittest 0
0x0 has 2 set

What is going on here?

[BrowserUk]

What is going on here?

I tweaked your code by adding a couple of extra print statements:

my $mask = hex($ARGV[0]);

print $mask;
print unpack 'H*', $mask;

my $setbits = unpack("%32b*", $mask);

printf("0x%x has %d set", $mask, $setbits);

And when I run it I get this output:

C:\test>junk 0xff
255    ## 3 bytes
323535 ## 6 nybbles with bit patterns 0011 0010 0011 0101 0011 0101 
0xff has 11 set

hex converts the string '0xff' to a number which you store in $mask;

unpack expects a string, so perl helpfully converts the number stored in $mask to a string in the default decimal representation '255'.

You are counting the bits in that 3 byte string.

To count the bits in the number, you need to tell perl that you want the binary representation of that number:

#! perl -slw
use strict;

my $mask = hex($ARGV[0]);

print $mask;
print unpack 'H*', pack 'C', $mask;

my $setbits = unpack("%32b*", pack 'C', $mask );
printf("0x%x has %d set", $mask, $setbits);

__END__
C:\test>junk 0xff
255
ff
0xff has 8 set