Perl bug ?

[vsespb]

#!/usr/bin/perl

use strict;
use warnings;

my $errors = undef;

sub ok
{
    my( $test, $name ) = @_;
    print "[[[$test]]] [[[$name]]]\n";
};

ok( ($errors && ($errors->[0] =~ /Journal file not found/i)), "some te
+xt 1 $errors->[0]" );
ok( ($errors && ($errors->[0] =~ /Journal file not found/i)), "some te
+xt 2 $errors->[0]" );

prints the following:

Use of uninitialized value in concatenation (.) or string at poc.pl li
+ne 14.
[[[ARRAY(0x137cd48)]]] [[[some text 1 ]]]
Use of uninitialized value in pattern match (m//) at poc.pl line 15.
Use of uninitialized value in concatenation (.) or string at poc.pl li
+ne 15.
Use of uninitialized value $name in concatenation (.) or string at poc
+.pl line 11.
[[[some text 2 ]]] [[[]]]

and by the way this code (with modified 'some text' strings)

#!/usr/bin/perl

use strict;
use warnings;

my $errors = undef;

sub ok
{
    my( $test, $name ) = @_;
    print "[[[$test]]] [[[$name]]]\n";
};

ok( ($errors && ($errors->[0] =~ /Journal file not found/i)), "some te
+xt 1" );
ok( ($errors && ($errors->[0] =~ /Journal file not found/i)), "some te
+xt 2" );

prints correct result:

Use of uninitialized value $test in concatenation (.) or string at poc
+.pl line 11.
[[[]]] [[[some text 1]]]
Use of uninitialized value $test in concatenation (.) or string at poc
+.pl line 11.
[[[]]] [[[some text 2]]]

perl 5.10.1 under Linux

[choroba]

You have stumbled upon autovivification. After expanding $error->[0] in the double quoted string, Perl creates the referenced array for you, so $error is now [].

[vsespb]

You are right.

#!/usr/bin/perl
my $errors = undef;
$errors->[0];
print $errors

prints ARRAY(0x15bad48). I didn't realize that autovivification happens even on read-only access =)

[vsespb]

But why ARRAY ref passed to subroutine ? Argument is

($errors && ($errors->[0] =~ /Journal file not found/i))

so it should be evaluated to false ?

[tinita]

the first call of ok():
the first argument is $errors && ($errors->[0] =~ /.../i) which results in $errors being passed as the first argument. before it is passed, array element 0 gets autovivivied though by usage in the second argument.

the second call:
$errors is now true, so the matching is executed and its result would the empty string ("false"). but since the matching is executed in list context, the result is an empty list, so what you wrote as a second argument becomes now the first argument.

[choroba]

Update: Disregard. See rather Re^5: Perl bug ?.

The order in which arguments to subroutines are processed is not guaranteed:

sub test { say for @_ }
test($x=0, $x=$x+1, $x++, ++$x);

Returns:

3
3
1
3

[Corion]

Also see the parallel discussion on RT in perl #116665 Undef evaluated to array in some conditions.

[vsespb]

or here https://rt.perl.org/rt3/Ticket/Display.html?id=116665

[salva]

The first warning is generated in "some text 1 $errors->[0]" because $errors->[0] is undefined.

That expression also has the side effect of autovivifying $errors and that causes the $errors check on the test on the following line to succeed.