Re: Re: Not Matt's Scripts

[davorg]

It might be very instructive to show before and after versions of the scripts.

You can do that easily enough at the moment by pulling down my versions and comparing them with Matt's. I might consider putting Matt's versions in my distribution as a lesson to us all, but I think he's quite protective on things like that.

Finally, CPAN has a scripts archive, though it isn't widely used.

The deputy librarian of CPAN has already shown great interest in these scripts. They will, no doubt, appear there in due course.

I would recommend writing modules which can be scripted via it's API instead of writing scripts proper.

There's a chance that something like that might happen much later. The problem is that Matt's scripts are so popular precisely because they are so easy to use. There's no need to install modules from CPAN or do anything that a novice webmaster might find confusing. If these scripts are to find any kind of popularity they have to be just as simple to use.

--
<http://www.dave.org.uk>

Perl Training in the UK <http://www.iterative-software.com>

[tye]

Just write the functionality of the script as a module and put "standard usage" of it at the end like:

package main;

require File::Basename;  File::Basename->import( qw(basename) );

if(  &basename( $0 )  eq  &basename( __FILE__ )  ) {
    require CGI;
    my $q= CGI->new();
    # ...
}

that way you can make one file that is both a module and an all-in-one CGI script. This might even help the modulephobic slowly learn to like modules. (:
        - tye (but my friends call me "Tye")

[simonm]

I've used a similar trick in the past, but rather than checking basename(), it's "unless ( caller ) { ...}", which seems to be equivalent.

[tye]

Ah, yes. Much better! I was also thinking of an improvement to prevent the example code from sticking around when it wasn't being used. For example:

package main;

BEGIN {
    my $isScript= ! caller(2);
    sub _isScript() { $isScript }
}
if(  _isScript  ) {
    require CGI;
    my $q= CGI->new();
    # ...
}
undef &_isScript;

would still require that the sample code be parsed the first time that the module is used but the optimizer would know to throw the resulting code away. Not quite as pretty, though.

Another hack to prevent even the work of parsing can be done:

package main;

unless(  caller  ) {
    my $code= do { local($/); <DATA> };
    my $file= __FILE__;
    my $line= __LINE__ + 5;
    eval "\n# line $line $file\n$code; 1"
      or  die "$@\n";
}
__END__
use CGI;
# ...
__END__

        - tye (but my friends call me "Tye")