Re: High-speed Date Formatting

[BrowserUk]

If can live with its limitations(¹), you could try something like this:

#! perl -slw
use strict;
use constant MONTHS => { qw[
    Jan 0 Feb 31 Mar 59 Apr 90 May 120 Jun 151
    Jul 181 Aug 212 Sep 242 Oct 272 Nov 303 Dec 334
] };

sub str2epoch {
    my( $d, $m, $y, $H, $M, $S ) = $_[0] =~
        m[^.... (\d\d) (...) (\d\d\d\d) (\d\d):(\d\d):(\d\d)] 
        or die "Bad format $_[0]";
        
    my $leaps =  int( ($y - 1970) / 4 + 0.5 );
    (((($y-1970)*365 +$leaps+MONTHS->{$m}+($d-1))*24 +$H)*60 +$M)*60 +
+$S;
}

my $date = 'Fri, 01 Mar 2013 01:21:14 +0000';;
print str2epoch( $date );

print scalar localtime str2epoch( $date );

print scalar localtime str2epoch( 'Fri, 12 Jul 2013 01:20:34' );;

__END__
C:\test\primes>..\str2epoch.pl
1362100874
Fri Mar  1 01:21:14 2013
Fri Jul 12 02:20:34 2013

And if you need a little more you might parse the numbers with unpack instead of the regex engine.

¹ Limitations include:

• No leap seconds;
• No daylight savings;
• No timezones;
• Only works for another 87 years.

[rjt]

No timezones;

This much is (sort of) trivial to fix. Add  ([+-]\d{4}) to the end of your regex, and then include - $tz/100*3600 - $tz%100*60 at the end of the expression.

sub str2epoch {
    my( $d, $m, $y, $H, $M, $S, $tz ) = $_[0] =~
        m/^.... (\d\d) (...) (\d\d\d\d) (\d\d):(\d\d):(\d\d) ([+-]\d{4
+})/
        or die "Bad format $_[0]";
        
    my $leaps =  int( ($y - 1970) / 4 + 0.5 );
    (((($y-1970)*365 +$leaps+MONTHS->{$m}+($d-1))*24 +$H)*60 +$M)*60 +
+$S
              - ($tz < 0 ? -1 : 1)*(substr($tz,1,2)*3600 + substr($tz,
+3)*60);
}

• No leap seconds;
• No daylight savings;
• Only works for another 87 years.

See my answer for timegm, which does slow things down, but is a bit more robust. ++ for pure-Perl that out-performs the "efficient" Time::Local routines and works in most all cases, though!

Edit: Updated $tz calc for fractional hours.

[BrowserUk]

No timezones; This much is trivial to fix....

Indeed, that is sufficiently efficient to make it silly not to include it. Thank you.

Though It seems silly not to let the regex do its work. I reformulated that as:

sub str2epoch {
    my( $d, $m, $y, $H, $M, $S, $tzs, $tzh, $tzm ) = $_[0] =~
        m[^.... (\d\d) (...) (\d\d\d\d) (\d\d):(\d\d):(\d\d) ([+-])(\d
+\d)(\d\d)]
        or die "Bad format $_[0]";

    my $leaps =  int( ($y - 1970) / 4 + 0.5 );
    (((($y-1970)*365 +$leaps+MONTHS->{$m}+($d-1))*24 +$H)*60 +$M)*60 +
+$S
    - ($tzs eq '-' ? -1 : 1)*$tzh*3600 + $tzm*60;
}

See my answer for timegm, which does slow things down, but is a bit more robust

All the others can be handled, but eventually you just end up with the morass that is DateTime which I have no time for :)

(There is a simple workaround for the 2100 problem, but it wouldn't come to mind as I write that. And the last version I wrote is archived on a CD somewhere.)

[hdb]

Another small speed up can be achieved by replacing

my $leaps =  int( ($y - 1970) / 4 + 0.5 );
    (((($y-1970)*365 +$leaps+MONTHS->{$m}+($d-1))*24 +$H)*60 +$M)*60 +
+$S;

with

(((int(($y-1970)*365.25-.5)+MONTHS->{$m}+$d)*24 +$H)*60 +$M)*60 +$S;

in my experiments between 5 to 10%. All other attempts using split and unpack are much slower. I found substr to be very fast:

sub str2epoch3 {
    (((int((substr($_[0],12,4)-1970)*365.25-.5)+
     MONTHS->{substr($_[0],8,3)}+substr($_[0],5,2))*24 +substr($_[0],1
+7,2))*60 +
     substr($_[0],20,2))*60 +substr($_[0],23,2);
}

about 60% faster than BrowserUk's code. I wonder whether there is something wrong...

Here is my full code:
Read more... (2 kB)

[sundialsvc4]

Only works for another 87 years.

This reminds me of a comment that I actually found in some source-code once:   “dig me up and I’ll fix it then.”