Re: Input Output Question

[poj]

Assuming you want the code in the code folder

#!perl
use strict;
use File::Copy;

opendir(DIR,'../input') or die "$!";
while (readdir DIR){
  unless (/^[.]{1,2}$/){
    print "copying $_\n";
    copy("../input/$_","../output/$_")   
      or die "Copy failed for $_ : $!";
  }
}

poj

[perlmonk007]

Thanks for the reply, but doesnt this code just copy the files. I want to parse the input for information

[poj]

Yes, it just copies the files. If you want to change them in the process then something like this

#!perl
use strict;
opendir(DIR,'../input') or die "$!";
while (readdir DIR){
  unless (/^[.]{1,2}$/){
    print "parsing $_\n";
    open IN,'<','../input/'.$_ 
      or die "Could not open $_ for input : $!";
    open OUT,'>','../output/'.$_ 
      or die "Could not open $_ for output : $!";
    while (my $line = <IN>){
      # process $line
      print OUT $line;
    }
    close IN; close OUT;
  }
}

poj

[rjt]

A reasonable approach. I have a couple of comments:

  unless (/^[.]{1,2}$/){
    open IN,'<','../input/'.$_ 
      or die "Could not open $_ for input : $!";

You skip `.' and `..' with the unless check, but don't do any checks after that, so if DIR contains any other directories, the script will die prematurely. That might not be an issue, depending on the OP's situation, but it's also easily avoided by replacing the unless with:

    next if -d;     # Skip directories.. OR:
  # next unless -f; # Skip anything that isn't a file

(You can then outdent what is currently in the unless { } block.)

Second, there is pretty much never a good reason not to use indirect filehandles to avoid potential namespace clashes with handles like DIR, IN, and OUT:

    open my $in, '<', '../input/' . $_;

Hope this helps.