creating unique list from elements in an array

[rimmern]

I have a file which contains lots of lines whose values are separated by | ie:

value 1|value 2|tom, chris, dave|value 4
value 1|value 2|peter, tom, dave|value 4

what I want to do is find all the unique names in all the instances of value3 in the file (ie tom, chris, dave & peter).

I know how to do it if the names are in an array but not if they are in an element in an array...

Any suggestions ?

Cheers, Digsy

[mirod]

The word unique nearly always call for a hash to be used. The solutiom is to extract the names, then to use them as (unique) keys to a hash.

#!/bin/perl -w
use strict;

my %unique_names;                          # this is the hash

while( <DATA>)
  { my @values= split /\|/;                # extract the fields (don't
+ forget to backslash the |)
    my @names= split /,\s*/, $values[2];   # extract the names
    foreach my $name (@names) 
      { $unique_names{$name}++; }          # we don't really care abou
+t the value, just the key
  }

my @unique_names= keys %unique_names;      # put the names back into a
+n array

print join "-", @unique_names;
print  "\n";

__DATA__
value 1|value 2|tom, chris, dave|value 4
value 1|value 2|peter, tom, dave|value 4

[Hofmator]

Very nice, mirod++, a good explanation! I just add the compact version - which is also a bit more efficient because it uses a hash slice:

my %unique;

@unique{ split /,\s*/, ( split /\|/ )[2] } = () while (<DATA>);

my @unique_names = keys %unique;
print join "-", @unique_names;
print "\n";

__DATA__
value 1|value 2|tom, chris, dave|value 4
value 1|value 2|peter, tom, dave|value 4

-- Hofmator

[mugwumpjism]

Is it a one-liner you want?

perl -ne '($a{$_} = 1) foreach split /,\s*/, (split /\|/)[2]; END { @a=sort keys %a; print "@a\n" }'

Shorter in shell :

awk -F\| '{print $3}' | sed 's/, */\
/g' | sort -u

[Sifmole]

mirod's answer is well explained, and Hofmator and mugwumpjism (what a beaut of a name) have shown how Perl can make something very... um.. concise.

I noticed that you are a novice monk and therefor might not be aware of the great deal of information that is available for you via the Search box at the top of your screen while on PerlMonks. Typing the words "unique elements" in the box returned many articles that contain a great deal of information related to your question.

One of the benefits of using the search would be that you would not have to wait for an answer to your question, it is already there. You might also find out quite a bit more that you had originally asked.

Good luck, welcome, and don't forget the Search box.