Condition on multiple lines and big file

[epimenidecretese]

Ciao guys,

I'm trying to solve the following problem but I'm not sure if perl it's the right tool for it. My data look like this:

Buenos    -    SPN    Buenos    B-GPE
Aires    -    SPN    Aires    I-GPE
Afghanistan    -    SPN    Afghanistan    B-GPE
Europa    -    SPN    Europa    B-GPE
UE    -    I    UE    B-GPE
Italia    -    SPN    Italia    B-GPE
Provincia    -    SS    Provincia    B-GPE
di    -    E    di    I-GPE
Lucca    -    SPN    Lucca    I-GPE
...

As yoou can see, whene there is an I-GPE it means that the name has to be composed whit the line before (i.e. Buenos Aires); when you have just B-GPE and the following line is also B-GPE, than it means they are different names.

Problem is the file is very big and I can't slurp it all at once.

I would like an output like the following

Buenos Aires
Afghanistan
Italia
...
Provincia di Lucca

Someone has any idea?

[kcott]

G'day epimenidecretese,

"I'm not sure if perl it's the right tool for it."

Perl would be an admirable tool for this task.

#!/usr/bin/env perl

use strict;
use warnings;

while (<DATA>) {
    my ($name, $code) = (split)[0,-1];
    print $code eq 'I-GPE' ? " $name" : $. == 1 ? $name : "\n$name";
}

print "\n";

__DATA__
Buenos  -   SPN Buenos  B-GPE
Aires   -   SPN Aires   I-GPE
Afghanistan -   SPN Afghanistan B-GPE
Europa  -   SPN Europa  B-GPE
UE  -   I   UE  B-GPE
Italia  -   SPN Italia  B-GPE
Provincia   -   SS  Provincia   B-GPE
di  -   E   di  I-GPE
Lucca   -   SPN Lucca   I-GPE

Output:

Buenos Aires
Afghanistan
Europa
UE
Italia
Provincia di Lucca

[VincentK]

Your solution is beautiful. I admire its simplicity.

[choroba]

No need to slurp the file. Process it line by line, remembering just the name:

my $name = q();
while (<>) {
    my @cols = split;
    if ('I-GPE' eq $cols[-1]) {
        $name .= $cols[0] . ' ';
    } else {
        print $name, "\n" if chop $name;
        $name = $cols[0] . ' ';
    }
}
# Do not forget to output the last name.
chop $name;
print "$name\n";

[Anonymous Monk]

And, for simpler situations of the same basic problem, also consider awk. This is the original tool from which, in one sense, the earliest Perl interpreters grew. It's still great for text-file munging.