Remove duplicates from Hash of Arrays

[Anonymous Monk]

Hello, this is probably a simple question but I'm a bit lost. I have a Hash of Arrays structure and I want to get every element of the arrays in one single array. This works but it doesn't remove the duplicates. Is there a simple way to remove duplicates at the same time?

my $HoA = {
   'music' => [9, 53, 3, 15],
   'conferences' => [7, 56, 15],
};
my @ids;
for my $ary ( values %$HoA ) {
   push(@ids,@$ary);
}
print "@ids";

# 9 53 3 15 7 56 15

[Kenosis]

Perhaps the following will be helpful:

use strict;
use warnings;

my %h;
my $HoA = {
    'music'       => [ 9, 53, 3,  15 ],
    'conferences' => [ 7, 56, 15, 53 ],
};

@h{@$_} = undef for values %$HoA;
my @ids = keys %h;

print "@ids";

# 53 56 3 7 9 15

What is this @h{@$_} = undef notation? See Hash from two arrays.

[Anonymous Monk]

Thanks, I will use this. After some reading up it seems setting each key to undefined can save memory when dealing with large arrays, as I sometimes will be.

[hdb]

my @ids = keys %{{ map { $_ => 1 } map { @$_ } values %$HoA }};

[LanX]

yes, instead of pushing to an array set keys in a hash.

keys %hash will return you a set w/o duplicates.

[wind]

From perldoc: How can I remove duplicate elements from a list or array?

- Miller

[Anonymous Monk]

Thank you for your helpful and informative replies