Subclassing Template::Stash to identify improper heavy lifting

[merlyn]

$client is doing a lot of heavy lifting (perhaps accidentally) in some Catalyst-driven Template Toolkit code. Apparently, it's far too easy to pass a DBIx::Class object into the stash, and then trigger things that end up hitting the database... from the view. That wouldn't be horrible, except the same exact queries are being used in multiple places in the templates, causing many redundant identical queries to the database per page hit. (Note aside: if this was Rose::DB... I'd trivially jump to Rose::DB::Object::Cached. Problem solved.)

I wanted a way to see what method calls were being invoked on the objects in the stash. Simple... just subclass Template::Stash! Now I get a list of the component invoking the method, the path from the root stash to the object, and the method call being made.

package Test::Stash;
use base qw(Template::Stash);

use strict;
use warnings;
use Scalar::Util qw( blessed reftype );

use Template::Config;

our @PATH;
our $BYPASS = 0;

sub _dotop {
  my ($self, $root, $item, $args, $lvalue) = @_;

  unless ($BYPASS) {
    my $rootref = ref $root;
    my $atroot  = (blessed $root && $root->isa(ref $self));

    if ($atroot) {
      @PATH = $item;
    } else {
      push @PATH, $item;
    }

    if (blessed $root && $root->can($item)) { # likely a method call
      if ($root =~ m{
              \A(
            DBIx::Class::QueryLog(::(Query|Analyzer))?
              |
            # (redacted Catalyst model class)
              |
            Template::Plugin::(Math|Date)
              |
            Moose::Meta::Class:: .*?
              )=}x) {
    ## ignore these
      } else {
    local $BYPASS = 1;
    my $component = $self->get(['component', 0, 'name', 0]);
    warn sprintf "%s: %s => %s\n",
      $component,
      join('.', @PATH),
      $root;
      }
    }
  }
  return (shift @_)->SUPER::_dotop(@_);
}

# warn "Loaded Test::Stash... before is $Template::Config::STASH";

$Template::Config::STASH = __PACKAGE__;

# warn "Loaded Test::Stash... after is $Template::Config::STASH";

1;