Parsing a date time string

[bangor]

In my script I need to accept date time strings in three formats:

2014-07-12
2014-07-12 1:00
2014-07-12 01:00

In this example I need to change "1:00" to "01:00" before passing to a DB query. This is how I am doing it:

sub parse_time {
    my $time = shift;
    return $time unless $time =~ m/\d{1,2}:\d{2}$/;
    return $time if $time =~ m/\d{2}:\d{2}$/;
    $time =~ s/(\d{1}:\d{2})$/0$1/;
    return $time;
}

It works, but it feels kludgy - any advice appreciated.

[Corion]

Why not fix the time unconditionally?

sub fix_time {
    my( $time )= @_;
    $time =~ s/^(\d:\d\d)$/0$1/;
    return $time
};

This replaces (if it finds) the leading single-digit number with a zero-padded number.

[bangor]

Thanks Corion, far more elegant. I made a small adjustment so it could accept the whole string:

sub fix_time {
    my $time = shift;
    $time =~ s/\s(\d:\d\d)$/ 0$1/;
    return $time;
}

[Lennotoecom]

while (<DATA>){
    printf "%04d-%02d-%02d %02d:%02d\n", m/\d+/g;
}



__DATA__
2014-07-1
2014-7-09 1:3
2014-07-12 01:5

output !

2014-07-01 00:00
2014-07-09 01:03
2014-07-12 01:05

[CountZero]

DateTime::Format::Natural can read many different formats of date and time strings and returns a DateTime object.