Re: Calculations before using lib;

[choroba]

To call the code during the compilation phase when use is resolved, use the BEGIN block:

use FindBin qw($Bin);
my $dir;
BEGIN {
    if ($Bin =~ /^(\/.+\/monkeyman\/bin)(\/.+)?/) {
    $dir = "$1/lib";
}
use lib $dir;
use MonkeyMan;

See perlsub for details.

[ikegami]

hum... passing undef to lib? Fixed:

use FindBin qw($RealBin);

my @extra_libs;
BEGIN {
    if ($RealBin =~ /^(\/.+\/monkeyman\/bin)(\/.+)?/) {
        push @extra_libs, "$1/lib";
    }
}

use lib @extra_libs;
use MonkeyMan;

or

use FindBin qw($RealBin);

use lib ();
BEGIN {
    if ($RealBin =~ /^(\/.+\/monkeyman\/bin)(\/.+)?/) {
        import->lib("$1/lib");
    }
}

use MonkeyMan;

Note the switch to $RealBin in order to handle symlinks.

[v_melnik]

Wow, thank you so much! I thought I've lost my sense %)

[afoken]

As perl needs to know the arguments for use lib before calling lib's import method, every expression used there is implicitly in a BEGIN block equivalent. So I often use a construct like this in my code:

#!/usr/bin/perl
use strict;
use warnings;
use FindBin ();
use lib do { (my $dir=$FindBin::Bin)=~s|/foo/|/bar/|; $dir };

This can also be used with taint mode to untaint the value of $FindBin::Bin:

#!/usr/bin/perl -T
use strict;
use warnings;
use FindBin ();
use lib do { $FindBin::Bin=~m|^(/.*)| or die "Can't find myself"; "$1/
+../lib" };

Alexander