#!/usr/bin/env perl
use Mojolicious::Lite -signatures;
use Data::Dump qw/dd pp/;

# morbo --listen='http://localhost:3000' serv.pl
# This code assumes a single thread / no forking!

my $single_client;
websocket '/' => sub ($c) {
	if ( defined $single_client ) {
		$c->app->log->debug('WebSocket opened, rejecting');
		$c->send("Too many client connections");
		$c->tx->finish;
		return;
	}
	$c->app->log->debug('WebSocket opened');
	$c->inactivity_timeout(45);
	$single_client = $c->tx;
	my $timer_id;
	$c->on(message => sub ($c, $msg) {
		if ( uc $msg eq "RUN" ) {
			if ( !defined $timer_id ) {
				$c->send("Starting to run");
				$timer_id = Mojo::IOLoop->recurring( 1 => sub {
					# pretend to be a fragile server
					if ( rand > 0.97 ) {
						$c->app->log->warn('Oops, disconnecting!');
						$single_client->finish;
					}
					elsif ( rand > 0.95 ) {
						$c->app->log->warn('Oops, freezing!');
						Mojo::IOLoop->remove($timer_id);
					}
					else { $c->send("Running ".(time-$^T)) }
				} );
			}
			else { $c->send("Already running") }
		}
		elsif ( uc $msg eq "STOP" ) {
			if ( defined $timer_id ) {
				$c->send("Stopping...");
				Mojo::IOLoop->remove($timer_id);
				$timer_id = undef;
			}
			else { $c->send("Not running") }
		}
		elsif ( uc $msg eq "HEARTBEAT" ) { }
		else { $c->send("Unknown command: $msg") }
	});
	$c->on(finish => sub ($c, $code, $reason=undef) {
		$c->app->log->debug("WebSocket closed ".pp($code, $reason));
		Mojo::IOLoop->remove($timer_id);
		$single_client = undef;
	});
	$c->send("Connected... RUN|STOP");
};
app->start