Re^2: parse a file TXT similar to XML -- flip-flop operator

[x-lours]

thank you for the reply.

i think that learning "flip flop" (knew knowledge for me) will help me to give a Perl answer to my colleague ;-)

the final array is sort of

[{index=>1, a => 'premiere valeur' ... , z => 'dernier mot'}, ..., {index=>77, a => 'autre valeur' ... , z => 'aurais-je le dernier mot'}]

[Discipulus]

Hello again,

you can easily modify the above code to have something like:

use strict;
use warnings;
use Data::Dumper;
my @AoH ;
my $current_hash = {};
while (<DATA>){
    chomp $_;
    if ( $_ =~ /objet => debut$/ .. /objet => fin$/){
        if ( /objet => debut$/ ){
            next;
        }
        elsif ( /objet => fin$/ ){
            push @AoH, $current_hash;
            $current_hash = {};
        }
        else{
            my ($key,$value) = split /\s+=>\s+/,$_;
            $current_hash->{ $key } = $value;
        }
    }
    else{
        print "unxpected content outside tags in line: [$_]\n";
    }
}
print Dumper \@AoH;
__DATA__
objet => debut
index => 1
a => "premiere valeur"
z => "dernier mot"
objet => fin
ALIEN LINE AFTER fin
objet => debut
index => 77
a => "autre valeur"
z => "aurai-je le dernier mot ?"
objet => fin

The above code use $current_hash as temporary container for key values pairs and need to be reset when fin is encountered. It outputs:

unxpected content outside tags in line: [ALIEN LINE AFTER fin]
$VAR1 = [
          {
            'a' => '"premiere valeur"',
            'index' => '1',
            'z' => '"dernier mot"'
          },
          {
            'z' => '"aurai-je le dernier mot ?"',
            'a' => '"autre valeur"',
            'index' => '77'
          }
        ];

L*

[x-lours]

Thanks for the explanations

very helpful to understand the flip-flop tool

[GrandFather]

You may find Flipin good, or a total flop? helpful. The flip flop operator family is home to dragons.

[Marshall]

If the output is an Array Of Hash, I don't see the need for the flip-flop operator, as cool as that thing is. Taking your DATA verbatim and assuming that 3 dots is the record separator, the code appears to me to be straightforward. This is not "one line", but at least for me, the code is very easy to understand. Please enlighten me if the Ruby complicated thing does something that this does not?

use strict;
use warnings;
use Data::Dumper;

my @structure;
my %temp;

while (<DATA>)
{   
   next unless /\S/;  # skip blank lines
   
   if (/^\.\.\./)     # 3 dots ends a record
   { 
       push (@structure, {%temp});
       %temp=(); 
   } 
   else
   {
       chomp;
       my ($key, $value) = split /\s+=>\s+/,$_;
       $temp{$key}=$value;
   }     
}
push (@structure, {%temp}) if (%temp); # possible last record
print Dumper \@structure;

=Output
$VAR1 = [
          {
            'a' => '"premiere valeur"',
            'objet' => 'debut1',
            'index' => '1'
          },
          {
            'objet' => 'fin',
            'z' => '"dernier mot"'
          },
          {
            'objet' => 'debut2',
            'index' => '77',
            'a' => '"autre valeur"'
          },
          {
            'z' => '"aurai-je le dernier mot ?"',
            'objet' => 'fin'
          }
        ];
=cut


__DATA__

objet => debut1
index => 1
a => "premiere valeur"
...
z => "dernier mot"
objet => fin
...
objet => debut2
index => 77
a => "autre valeur"
...
z => "aurai-je le dernier mot ?"
objet => fin

UPDATE: I looked at this thing again and I think I see a possible interpretation error of your DATA on my part. I work with some XML formats and this idea of using a specific key to indicate the start or the end of the record is my opinion, ill advised. Usually XML keys usually are not guaranteed to come in a specific order. However usually there will be clear "end of record" indication. In some files I parse, that is "\n". Here I assumed just a blank line, or end of file.

so here is updated code:

use strict;
use warnings;
use Data::Dumper;

my @structure;
my %temp;

while (<DATA>)
{     
   if (!/\S/)     # blank line ends a record
   { 
       push (@structure, {%temp}) if (%temp); # possible null record
       %temp=(); 
   } 
   else
   {
       chomp;
       my ($key, $value) = split /\s+=>\s+/,$_;
       $value =~ tr/"//d;   # remove double quotes
       $temp{$key}=$value;
   }     
}
push (@structure, {%temp}) if (%temp); # possible last record
print Dumper \@structure;

=Output
$VAR1 = [
          {
            'a' => 'premiere valeur',
            'b' => 'some value',
            'index' => '1',
            'z' => 'dernier mot',
            'objet' => 'fin'
          },
          {
            'a' => 'autre valeur',
            'index' => '77',
            'objet' => 'fin',
            'z' => 'aurai-je le dernier mot ?'
          }
        ];

=cut


__DATA__

objet => debut
index => 1
a => "premiere valeur"
b => "some value"
z => "dernier mot"
objet => fin

objet => debut
index => 77
a => "autre valeur"
z => "aurai-je le dernier mot ?"
objet => fin

[x-lours]

your updated code is what i need.

Thank you