Hex dump

[kschwab]

Description:

subroutine to print a hexdump of a string. I saw some discussion in the CB about needing such a thing.

Update: Also see HexView by OeufMayo.

sub hdump {
    my $offset = 0;
    my(@array,$format);
    foreach my $data (unpack("a16"x(length($_[0])/16)."a*",$_[0])) {
        my($len)=length($data);
        if ($len == 16) {
            @array = unpack('N4', $data);
            $format="0x%08x (%05d)   %08x %08x %08x %08x   %s\n";
        } else {
            @array = unpack('C*', $data);
            $_ = sprintf "%2.2x", $_ for @array;
            push(@array, '  ') while $len++ < 16;
            $format="0x%08x (%05d)" .
               "   %s%s%s%s %s%s%s%s %s%s%s%s %s%s%s%s   %s\n";
        } 
        $data =~ tr/\0-\37\177-\377/./;
        printf $format,$offset,$offset,@array,$data;
        $offset += 16;
    }
}

Update: Fixed the map() in a void context problem. Thanks merlyn. For the curious, it sort of evolved into a void context as I cleaned up the subroutine before posting it to perlmonks.

[merlyn]

I really dislike the "void map" there, for things like:

map {$_ = sprintf('%2.2x',$_)} @array;

What's wrong with simply:

$_ = sprintf "%2.2x", $_ for @array;

It even comes in at fewer characters, as well as running faster!

-- Randal L. Schwartz, Perl hacker

[tokai]

I liked the output of this function, so I used it for debugging purposes for a while... but in the end I wrote my own simplified variant with some other ideas from here and there which produces exactly the same output:

sub hexdump($)
{
    my $offset = 0;
        
    foreach my $chunk (unpack "(a16)*", $_[0])
    {
        my $hex = unpack "H*", $chunk; # hexadecimal magic
        $chunk =~ tr/ -~/./c;          # replace unprintables
        $hex   =~ s/(.{1,8})/$1 /gs;   # insert spaces
        printf "0x%08x (%05u)  %-*s %s\n",
            $offset, $offset, 36, $hex, $chunk;
        $offset += 16;
    }
}