for_list and sorting key/value hash pairs

[ibm1620]

I am finding the experimental for_list feature in v5.36 very useful - mostly when combined with the indexed builtin or when processing hashes. However, I do frequently want to process hash pairs sequentially by key (similar to for my $k (sort keys %h) { ... }) so I set about looking for a way to do it in a for_list. The best I've come up with is:

#!/usr/bin/env perl
use v5.36;
no warnings q/experimental::for_list/;
use List::AllUtils qw/pairs unpairs/;

my %h = map { ( $_, rand ) } ('a' .. 'z');

for my ($k, $v) ( unpairs (sort { $a->key cmp $b->key } pairs %h) ) {
    say "$k => $v";
}

which is too verbose to be practical. I noticed reading the doc for key/value pair list functions the following:

NOTE: At the time of writing, the following pair* functions that take a block do not modify the value of $_ within the block, and instead operate using the $a and $b globals instead. This has turned out to be a poor design, as it precludes the ability to provide a pairsort function. Better would be to pass pair-like objects as 2-element array references in $_, in a style similar to the return value of the pairs function. At some future version this behaviour may be added. Until then, users are alerted NOT to rely on the value of $_ remaining unmodified between the outside and the inside of the control block.

I don't understand the issue they're raising, but it does sound like a pairsort is what I need. In the meantime, can anyone suggest a better way to sort the pairs when iterating with a for_list over a hash?

[hv]

My first inclination would be to construct the list in older style:

for my($k, $v) (map +($_, $h{$_}), sort keys %h) {
  say "$k => $v";
}

But note that you can take a key-value hash slice to shorten it, like so:

for my($k, $v) (%h{sort keys %h}) {
  say "$k => $v"
}

In a hash slice, if you use @ as the sigil, it will give just the values in the hash; if you use % as the sigil, it gives key-value pairs:

% perl -E '%h = (1..6);
  say "arrayish slice"; say for @h{1,5};
  say "hashish slice"; say for %h{1,5}'
arrayish slice
2
6
hashish slice
1
2
5
6
%

[tybalt89]

for my ($k, $v) ( map { $_, $h{$_} } sort keys %h )

untested :)

[davido]

for_list is certainly useful, and even for arrays. But in this case it's reasonably clear, and more concise to just use traditional pre-5.36 Perl.

my %h = map { $_, rand } 'a'..'z';

print "$_ => $h{$_}\n" for sort keys %h;