Failed match not stored

[BillKSmith]

The match operator returns an (unspecified)false value when the match fails. Why is that value not stored in this case?

use strict;
use warnings;
use version '5.38';
use feature 'say';
use Test::More tests=>1;

my @arry1 = ('string'=~ m/str/, 'second');
my @arry2 = ('string'=~ m/foo/, 'second');
# no value stored for failed match.
is $arry2[1], $arry1[1];

RESULT

not ok 1
#   Failed test at tryit2.pl line 10
#          got: undef
#     expected: 'second'
# Looks like you failed 1 test of 1.

[jwkrahn]

In list context a failed match returns an empty list.

[BillKSmith]

Thanks for the simple answer. The original problem was more subtle than my example, but in both cases, I failed to recognize the list context.

[duelafn]

Thus, you can fix the issue in a couple ways. Explicitly forcing scalar context:

use Test::More tests=>1;

my @arry1 = (scalar 'string' =~ m/str/, 'second');
my @arry2 = (scalar 'string' =~ m/foo/, 'second');
is $arry2[1], $arry1[1];

or choosing your false value (and implicitly forcing scalar context)

use Test::More tests=>1;

my @arry1 = (('string' =~ m/str/ or 0), 'second');
my @arry2 = (('string' =~ m/foo/ or 0), 'second');
is $arry2[1], $arry1[1];

[BillKSmith]

I already had a 'workaround' similar to your second solution. I will adopt your first suggestion because it explicitly addresses the real issue rather than working around it.