Strange behavior of array in scalar context

[xavier8854]

Hi,
Why does scalar(@array) return 1 for an empty array ?
Code :

my @executions = $jobInfo->{'content'}{'executions'};
print Dumper (@executions, scalar(@executions));

result is :

$VAR1 = [];
$VAR2 = 1;

I use this syntax regulary, never happened.
Thanks for your wisdom,
FTR, this is perl 5.38.2 on Ubuntu 22.0.4
Xavier

[Corion]

First of all, your debugging is flawed. You want to pass arrays and hashes as references to Data::Dumper:

print Dumper \@executions, scalar(@executions);

Second, you are copying the reference into @executions, not the contents. This means that @executions will only ever contain a single element:

my @executions = $jobInfo->{'content'}{'executions'};

What you likely wanted is to copy the array items:

my @executions = $jobInfo->{'content'}{'executions'}->@*; # requires P
+erl 5.36+

# Alternatively

my @executions = @{ $jobInfo->{'content'}{'executions'} };

[Anonymous Monk]

my @executions = $jobInfo->{'content'}{'executions'}->@*; # requires P
+erl 5.36+

postderef was available much earlier than 5.36:
https://www.perl.com/article/68/2014/2/13/Cool-new-Perl-feature--postfix-dereferencing/

[Anonymous Monk]

my @executions = $jobInfo->{'content'}{'executions'};

This puts whatever happens to be returned on the right-hand side into the first slot of the array @executions. It just happens that what you get is from the RHS not an empty array, but an empty arrayref. And this arrayref happens to occupy the first slot of the array @executions. Therefore, the array @executions has one element.

See what print Dumper \@executions; returns instead.

To turn an arrayref into an array (i.e. copy its contents to an array), you need to dereference it, or you can just keep using it as an arrayref. I usually do the latter.

# Dereference and copy contents
my @executions = @{ $jobInfo->{'content'}{'executions'} }; 

# Just use it as an arrayref
my $executions = $jobInfo->{'content'}{'executions'};
print scalar @$executions, "\n";
print "element 0 is ", $executions->[0], "\n";

[xavier8854]

Stangely, the syntax :

$#executions

returns correctly 0

[hippo]

That indicates that the array does have one element.

my @x = ();
my @y = (99);
print "x count is $#x, y count is $#y\n";

results in

x count is -1, y count is 0

[ikegami]

s/count/max index/g