Re^2: appending to html at beginning (updated)

[haukex]

Hi Discipulus,

you open a tempfile, you write $new_lines to it then you open the existing original file for read and write it's lines to the temp one. Finally you swap files.

I was considering posting this, but went with the Tie::File example instead. But since I happened to be working with code that uses the rename method just the other day, I had the basics handy, here it is:

#!/usr/bin/env perl
use warnings;
use strict;

use File::Temp qw/tempfile/;
use File::Basename qw/fileparse/;

my $filename = "/tmp/test.html";
my @to_insert = ( '<p>Hello,',
    'World! It is '.gmtime(time).' UTC</p>' );

open my $ifh, '<', $filename or die "open $filename: $!";

my ($basename,$path) = fileparse($filename);
my ($tfh,$tfn) = tempfile( $basename.'_XXXXXXXXXX',
    SUFFIX=>'.tmp', DIR=>$path );
#warn "Debug: writing to $tfn\n";

# change the lines of the input file however you wish here
my $found;
while (<$ifh>) {
    print $tfh $_;
    if (/<!--\s*INSERT\s+HERE\s*-->/i) {
        $found=1;
        print $tfh "$_\n" for @to_insert;
    }
}

close $ifh;
close $tfh;
chmod(0666&~umask,$tfn) or warn "Couldn't chmod $tfn: $!";
if (!rename($tfn, $filename)) {
    my $e=$!;  unlink($tfn);
    die "Renaming $tfn to $filename failed: $e";
}
#warn "Debug: Renamed $tfn to $filename\n";
die "Marker not found" unless $found;

For those who don't know, the advantage is that rename is an atomic operation on many filesystems, meaning that on such filesystems, the filename (in this case /tmp/test.txt) will always exist and always point to either the old version or the new version of the file, and never point to an "in-between" version where the file is still being written.

Update: Forgot that unlink can set $!, so I preserved its value. Update 2: The code now modifies the file in the same way my other example does. Update 3, 2017-02-07: I was just reminded of the issue that files created by File::Temp have 0600 permissions, so I added the chmod to the code above.

Update 2017-09-20: I provided an updated version of the above code using my new module File::Replace here: [RFC] File::Replace

Regards,
-- Hauke D