Is there an isArray() in Perl?

[xorl]

I need to figure out if an element in an array is an array. I have something like:

my @array=("red", "blue", "green", ["purple", "orange"]);

I want to test each element and if the element is array I want it to do something special.

Thanks

Originally posted as a Categorized Question.

[Flame]

Try:

foreach $item (@array){
   if(ref($item) eq 'ARRAY'){
      #It's an array reference...
      #you can read it with $item->[1]
      #or dereference it uisng @newarray = @{$item}
   }else{
      #not an array in any way...
   }
}

Hope this helps

[suaveant]

look at the ref() function in perl, it tells you the type of ref you have.

[jacques]

Alternatively, you can use universal.pm

use UNIVERSAL 'isa';

foreach $item (@array) {

if (isa($item, 'ARRAY')) {
print "We've got an array!!\n";
}

}

[salva]

UNIVERSAL is available even without use'ing it, so the previous code snippet can be rewritten as:

foreach $item (@array) {
  if (UNIVERSAL::isa($item, 'ARRAY')) {
    print "We've got an array!!\n";
  }
}

[ysth]

Correct; the only point of use'ing UNIVERSAL is to import the function(s)...which he does.

[jdporter]

The reftype function in module Scalar::Util is good. It returns 'ARRAY' for any array reference, even if it's blessed.

[swampyankee]

The ref function will return "ARRAY" if its argument is an unblessed array reference.

[jdporter]

Right. That makes it inappropriate as an isArray function, since it returns false for some arrays.

[naikonta]

If you work with normal array variables (not a reference ones), then you will never need such function. The sigil @ tells your right away that it's an array.

[Molt]

If there's a chance of wanting to catch bless'ed arrays, or dealing with psychologically nasty code, such as my $item=bless {}, 'ARRAY', then it's best to be paranoid and check if you can actually treat the item as an array.

The following code snippet shows a function that does this kind of check:

for my $item (@array) {
  print "We've got an array" if is_array($item);
}

sub is_array {
  my ($ref) = @_;
  # Firstly arrays need to be references, throw
  #  out non-references early.
  return 0 unless ref $ref;

  # Now try and eval a bit of code to treat the
  #  reference as an array.  If it complains
  #  in the 'Not an ARRAY reference' then we're
  #  sure it's not an array, otherwise it was.
  eval {
    my $a = @$ref;
  };
  if ($@=~/^Not an ARRAY reference/) {
    return 0;
  } elsif ($@) {
    die "Unexpected error in eval: $@\n";
  } else {
    return 1;
  }

}