The @_ array and the lexical variables

[G4143]

Perl noob here... I thought I understood the @_ array and its purpose with subroutines but then I found these usages that made run here for answers..

Readonly::Hash my %hash => (data => $data);
const my $min => 1;
const my $max => 10;
open (my $infile, '<', "datafile");
chomp(my $line = <STDIN>);

Now I read and experimented and arrived at the simple subroutine below which reproduces the above but it makes me raise a simple question - What kind of Perl voodoo is happening when you pass my $num to a subroutine parameter list?

sub doIt {
  $_[0] = $_[1];
}

doIt my $num => 4143;

So what is happening with the @_?

[choroba]

Elements of @_ are aliases to the arguments, i.e. when you change $_[0] directly, you change the original argument, which in this case happens to be $num, respectively %hash.

See perlsub:

The array @_ is a local array, but its elements are aliases for the actual scalar parameters. In particular, if an element $_[0] is updated, the corresponding argument is updated (or an error occurs if it is not updatable).

[G4143]

Could you demonstrate that behaviour with a normal array or how I would arrive at that behaviour? Something like:

my @arr = (my $one, my $two, my $three);

[choroba]

No, it's the magic behind @_ and calling a subroutine that causes the aliasing. Normal arrays don't alias.

Another aliasing construct if for:

my $x = 1;
for my $y ($x) {
    $y++;
}
print $x;  # 2

See also Data::Alias .

[ikegami]

our @arr; local *arr = sub { \@_ }->( my $one, my $two, my $three );

or

use Data::Alias qw( alias );

alias my @arr = ( my $one, my $two, my $three );

or

use feature qw( refaliasing );

my @arr;
\$arr[@arr] = \my $one;
\$arr[@arr] = \my $two;
\$arr[@arr] = \my $three;

[LanX]

No voodoo but well documented.

See also call by reference in perlglossary and call by reference in WP.

Please note that "reference" here is CS terminology and doesn't exactly mean Perl's idea of reference but rather Perl's "alias".