Fixing: Experimental keys on scalar is now forbidden

[TheVend]

Moving to perl 5.24.0 I get the following:
Experimental keys on scalar is now forbidden...
My line of code is:
@tempCustArray = keys { map { $_ => 1 } @webCustomers };
I call on the Monks for their wisdom.

[ikegami]

Better solution:

my %seen;
my @uniqWebCustomers = grep !$seen{$_}++, @webCustomers;

Better yet:

use List::Util qw( uniq );

my @uniqWebCustomers = uniq @webCustomers;

[kennethk]

I agree with the "Better yet," but in situations where I do something like option 1, I like to wrap it in a do block to maintain tight scoping:

my @uniqWebCustomers = do{
    my %seen;
    grep !$seen{$_}++, @webCustomers;
};

[ikegami]

If you're going to add a block, make it a sub.

sub uniq { my %seen; grep !$seen{$_}++, @_ }

my @uniqWebCustomers = uniq @webCustomers;

[NetWallah]

Try hash instead of hashref. "+" added to avoid mis-interpretation of "map":

@tempCustArray = keys %{+ map { $_ => 1 } @webCustomers };

UPDATE 1: That passes syntax, but does not seem to give the desired result .. still testing ....

Update 2: This works:

my @t = keys %{+{ +map { $_ => 1 } qw|uno dos tres| }}

Now I have to figure out WHY it works..... and pre-Update1 does not..

Update 3: The "+" signs are unnecessary .. this works:

@tempCustArray = keys %{{ map { $_ => 1 } @webCustomers }}

So - it seems to be a question of why the extra braces are required.

[ikegami]

it seems to be a question of why the extra braces are required.

The outer %{ ... } is a hash dereference.

The inner { ... } creates a hash and returns a reference to it.

In your first snippet, you have a hash dereference, but no hash.

[NetWallah]

Thanks for the clarification, ikegami (++).

The postfix syntax below also works, and is easier to read.

my @t = keys {map { $_ => 1 } qw|uno dos tres| }->%*;

[TheVend]

WOW, that worked like a champ! Thank you so much!