Sorting an array of lines

[Quadzilla]

Is there an easy way to sort this example element from my @array on the value called p_inuse?

@array has a bunch of lines that look like this:

 10.47.147.0   Free: 63    In-use: 99    P_InUse: 66

I want to sort on the last numeric value (here, the 66) so that I can print the array later in decending order.

Thanks

2002-02-09 Edit by Corion: Removed some CODE tags.

[indapa]

Take a look at Complex Sorting, it's an excellent explaination of what you need.

#!/apps/bin/perl -w

my (@array, @sorted) =();
while (<>) {
    chomp;
    push (@array, $_);
}

@sorted = 
    map {$_->[0]}
    sort {$a->[1] <=> $b->[1]}
    map {
        my ($sortvalue) = /(\d+)$/;
    [$_,$sortvalue];
    } @array;



print "@sorted\n";

[Juerd]

print "@sorted\n";

Probably not what you want. You chomped the initial list, and $" is usually not set to \n.

Either don't chomp (don't chomp unless you need the data chomped) and print @sorted; or print "$_\n" for @sorted; or print map "$_\n", @sorted;.

2;0 juerd@ouranos:~$ perl -e'undef christmas'
Segmentation fault
2;139 juerd@ouranos:~$

[Juerd]

Just first-post trolling. In little time, there will be better answers, probably using optimization techniques like the famous Schwartzian Transform.



print sort {
    my ($aa) = $a =~ /(\d+)\s*$/;
    my ($bb) = $b =~ /(\d+)\s*$/;
    $bb <=> $aa;

} <DATA>;

__DATA__
 10.47.147.0   Free: 63    In-use: 99    P_InUse: 61
 10.47.147.0   Free: 63    In-use: 99    P_InUse: 65
 10.47.147.0   Free: 63    In-use: 99    P_InUse: 70
 10.47.147.0   Free: 63    In-use: 99    P_InUse: 69
 10.47.147.0   Free: 63    In-use: 99    P_InUse: 63
 10.47.147.0   Free: 63    In-use: 99    P_InUse: 66


Have fun

2;0 juerd@ouranos:~$ perl -e'undef christmas'
Segmentation fault
2;139 juerd@ouranos:~$

[CharlesClarkson]

Since you have some leading spaces in your lines, I used column 8 for the sort instead of column 7. '-8n' means sort descending on column 8 numerically.

use Sort::Fields;
my @sorted = fieldsort ['-8n'], @array;




HTH,
Charles K. Clarkson
Clarkson Energy Homes, Inc.