Re: Regex Tuning

[brianarn]

Because I'm in such a great mood today, I'll share with you a code sample from my wonderful "CGI Programming With Perl, 2^nd edition" book from O'reilly - this book is great if you intend to do a lot of CGI stuff, it really helped me get started and helps me on a regular basis. :)

sub validate_email_address {
  my $addr_to_check = shift;
  $addr_to_check =~ s/("(?:[^"\\]|\\.)*"|[^\t "]*)[ \t](/$1/g;

  my $esc         = '\\\\';
  my $space       = '\040';
  my $ctrl        = '\000-\037';
  my $dot         = '\.';
  my $nonASCII    = '\x80-\xff';
  my $CRlist      = '\012\015';
  my $letter      = 'a-zA-Z';
  my $digit       = '\d';
  my $atom_char   = qq{ [^$space<>\@,;:".\\[\\]$esc$ctrl$nonASCII]};
  my $atom        = qq{ $atom_char+ };
  my $byte        = qq{ (?: 1?$digit?$digit |
                            2[0-4]$digit    |
                            25[0-5]         ) };
  my $qtext       = qq{ [^$esc$nonASCII$CRlist"] };
  my $quoted_pair = qq{ $esc [^$nonASCII] };
  my $quoted_str  = qq{ " (?: $qtext | $quoted_pair )* " };
  my $word        = qq{ (?: $atom | $quoted_str ) };
  my $ip_address  = qq{ \\[ $byte (?: $dot $byte ){3} \\] };
  my $sub_domain  = qq{ [$letter$digit]
                        [$letter$digit-]{0,61} [$letter$digit]};
  my $top_level   = qq{ (?: $atom_char ){2,4} };
  my $domain_name = qq{ (?: $sub_domain $dot )+ $top_level };
  my $domain      = qq{ (?: $domain_name | $ip_address ) };
  my $local_part  = qq{ $word (?: $dot $word )* };
  my $address     = qq{ $local_part \@ $domain };

  return $addr_to_check =~ /^$address$/ox ? $addr_to_check : "";
}

I know it's not the easiest of things to read when you're new, but hey - it'll validate just about any legal mail you can throw at it, and it even supports [e-mail] where the end is more than the normal 2 or 3 chars like .uk or .com etc. It currently supports from 2-4 characters, but can easily be expanded by adjusting the {2,4} range in $top_level.

HTH,
~Brian

[Matts]

can easily be expanded by adjusting the {2,4} range in $top_level.

Important to do that since .museum is now a valid TLD.