decimal to binary

[Punto]

Is there any way to convert a decimal number to a binary number? and vice versa?

Thanks.

[btrott]

Here's a bintodec function:

    sub bintodec {
        unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
    }

Taken from the pack manpage.

And this seems to work for a dectobin, although there's probably a faster way w/o using join:

    sub dectobin {
        join '', unpack "B32", pack "N", shift;
    }

[dempa]

The answer btrott gave is ofcourse universal and good, but you can also do this (but only in Perl 5.6.0 I think):

   print bin2dec(0b1101) . "\n";
   print dec2bin(13) . "\n";

   sub bin2dec {
       return(sprintf "%d",shift);
   }

   sub dec2bin {
       return(sprintf "%b",shift);
   }

Update: I forgot to mention that oct() can be used (in Perl 5.6.0) to convert from binary to decimal:

   perl -e 'print oct("0b1101") . "\n";'

[merlyn]

Ouch. Your bin2dec is doing absolutely nothing but making sure it's an integer.

You really need to think in terms of "numbers" being processed, not "decimal numbers". The value 47 internally is not in decimal or binary, conceptually. It's just forty seven things. So $a = 47 starts with a decimal 47 as I type it in, then converts that to the concept of 47, and assigns that to $a.

So what we really have are building blocks:

$decimal = sprintf "%d", $num; # or trivially removed, since automatic
$octal = sprintf "%o", $num;
$hex = sprintf "%h", $num;
$binary = sprintf "%b", $num; # 5.6 only
$num = 0+ $decimal; # or trivially removed, since automatic
$num = oct($octal);
$num = unpack "N", pack "H*", $hex;
$num = unpack "N", pack "B*", $binary;

Then combine as needed.

-- Randal L. Schwartz, Perl hacker

[dempa]

Ouch. Your bin2dec is doing absolutely nothing but making sure it's an integer.

Ehh.. but it does the job in question, right? Converting a supplied binary number to decimal.

update: OK, maybe that's not the definition of "decimal". Everyone happy if we rename the sub to bin2int? :)