Saving certain email attachements using MIME::Tools

[neilwatson]

Brothers and Sisters,

I'm creating a script that will save certain email attachments and ignore others:

my @attypes= qw(application/gzip
                application/x-tgz
                application/zip
                application/bzip2
);
my ($x, @attachment, $attachment, @attname);

SNIP
foreach $x (@attypes){
            print "x = $x subentity =".$subentity->mime_type."\n";
            if ($subentity->mime_type =~ m/$x/i){
                $attachment = join "", @{$subentity->body};
                push @attachment, $attachment;
                print $subentity->head->get('Filename')."\n";
                if ($subentity->mime_type =~ m/filename="(.*)"/i){
                    push @attname, $1;
                    last;
                }
            }

The prints are for debugging. Question, I can figure our the mime-type but how do I get the filename and the contents of that file?

Thank you,

Neil Watson
watson-wilson.ca

[jlongino]

I believe this will do what you want.

#!/usr/local/bin/perl
use MIME::Parser;
use strict;
use warnings;

## directory to store all parsed MIME parts
my $outputdir = "./mimemail";
my $parser = new MIME::Parser;
$parser->output_dir($outputdir);

## this creates files for all parts
my $entity = $parser->read(\*STDIN);
my $num_parts = $entity->parts;

## define attachment types to keep -- notice all lowercase
## add as many types as you like.
my %type_ok = (
   'application/octet-stream' => 1
);

if ($num_parts > 0) {
    for (my $i = 0; $i < $num_parts; $i++) {
        my $part = $entity->parts($i);
        ## note: lc so types have a better chance of matching
        my $type = lc $part->mime_type;
        my $bh = $part->bodyhandle;
        ## delete parts we don't want
        if (! exists $type_ok{$type}) {
           my $status = system("rm '$bh->{MB_Path}'");
           die $! unless $status == 0;
        }
    }
}

The program is executed like this:

program < single.message.mime

Update: './mimemail' directory should already exist. Also removed unneeded 'my $msg_body;' line.

--Jim

[blahblahblah]

I think this would work:

$body = $entity->bodyhandle;
$filename = $body->path;

[neilwatson]

$body returns: MIME::Body::InCore=HASH(0x83a39ac) while $filename comes out blank.

Update

  foreach $x (@attypes){
    if ($subentity->mime_type =~ m/$x/i){
      $attachment = $subentity->bodyhandle->print();
      push @attachment, $attachment;
      print "x = $x subentity =".$subentity->mime_type."\n";
      push @attname, $subentity->head->mime_attr('content-disposition.
+filename');
     } 
  }

The attachment prints out but is not stored in $attachment. @attname now holds the attachment name correctly. All that remains is figuring out how to store the attachement into a variable for later use.

Neil Watson
watson-wilson.ca

[blahblahblah]

You're setting $attachment to the return value of the print() method. The perldoc for MIME:Body doesn't say anything about print() returning anything. There are other methods that look like they'll do what you want, like as_string() and as_lines().

MIME::Tools has some of the better documentation I've seen for modules, with lots of examples. You should run "perldoc MIME::Body" or look at these pages on perldoc.com:
http://www.perldoc.com/cpan/MIME-tools.html
http://www.perldoc.com/cpan/MIME/Body.html

[neilwatson]

Thanks to everyone's help, I have a working example of code at this node.

Neil Watson
watson-wilson.ca

[Anonymous Monk]

You might need MIME::Parser