How do I pick anything that is in array A that is NOT in array B

[Anonymous Monk]

How do I pick anything that is in array A that is NOT in array B

Originally posted as a Categorized Question.

[Anonymous Monk]

The lingo for your desired operation is the difference of two arrays. This has already been answerd in How can I find the union/difference/intersection of two arrays?. Here's another solution which doesn't use a set hash:

@a_minus_b = grep { my $a = $_; not grep { $a eq $_ } @b } @a;

[gansi]

use strict;

my @A = (2..5);
my @B = (4..7);

my @A_not_B;

foreach my $data ( @A )
{
    push @A_not_B, $data
        unless grep { $_ eq $data } @B;
}
print "FINAL :: @A_not_B \n";

[MidLifeXis]

This is O(N*M) (where N is sizeof A, and M is sizeof B). You can do it in O(N+M) by building a hash with the contents of B, and using that for your test (instead of grep).

my %B = map { $_ => 1 } @B;
foreach my $data ( @A ) {
    push @A_not_B, $data unless $B{$data};
}

You could also replace the foreach loop with:

@A_not_B = grep { ! $B{$_} } @A;

If N and M are large, the difference between O(N+M) and O(N*M) can be substantial. For the sample set, it is probably not noticeable.