Character positioning

[Anonymous Monk]

First off, while this is a question related to a homework assignment, I certainly don't want anyone doing my homework for me. Mostly, what I'm looking for is some idea as to a reasonable path to my goal, with maybe some warnings as to what to watch out for along the way. If someone want's to give me some actual code, keen, but that's not my primary goal.

I'm working on a CGI hangman program, using the CGI.PM module to handle the CGI stuff. What I'm stuck on right now is the subroutine to reveal the word, called (imaginatively enough) reveal_word.

My data structure looks like this:

%current = ( 
 'word'       => "", 
 'tries_left' => "", 
 'letters'    => "", 
 'revealed'   => "",
);

I start by setting revealed to be a number of _ equal to how many letters are in word. Then a user makes a guess, I check and see if it's in the word, and if it is, I want to have revealed end up getting the guess (one letter) into the right "slot", with the rest of them still being _. So a guess of c with the word being cat should give me c__.

The problem is, I've no idea how to do this. It's not adding the guessed letter, it's adding it in the right place I can't figure out. How can I put that letter where I want it? Is there some clever thing involving s/// I should be trying? Or should I be completely rebuilding what goes into $current{'revealed'}? Or is there some perl command that'll just do it for me that I just can't find anywhere in my friendly O'Reilly books or over on CPAN?

Thanks, ~Pax

update (broquaint): added some formatting and changed the title (was Lost...)

[djantzen]

Okay, here's an approach using substr to get you started:

my $word = 'cat';
my $mask = '___';
my $guess = 'c';

substr($mask, 0,1) = $guess;

print $mask;

You'll still need to figure out the indexes at which the characters need to be replaced, but that shouldn't be too hard.

[Chmrr]

Here's another way of looking at your problem that may suggest to you a possible solution; you've got a bunch of characters in a string -- the word. For each letter, either it's a letter that's been guessed, or it isn't. If it has been guessed, just show the letter. Otherwise, show an underscore. You may find that treating the word as an array this way is useful.

perl -pe '"I lo*`+$^X$\"$]!$/"=~m%(.*)%s;$_=$1;y^`+*^e v^#$&V"+@( NO CARRIER'

[japhy]

I would use the following method:

while ($current{word} =~ /$letter/g) {
  substr $current{revealed}, $-[0], 1, $letter;
}

This uses the @- array which holds the offsets of the entire match and the $1 (etc.) variables. Basically, $-[0] gives me the offset in the string we matched against where the pattern started. Since the real word and the revealed word are "identical", the offsets are the same.

_____________________________________________________
Jeff[japhy]Pinyan: Perl, regex, and perl hacker, who'd like a job (NYC-area)
s++=END;++y(;-P)}y js++=;shajsj<++y(p-q)}?print:??;

[mce]

Hi,

All these approches are fine, but one seems to forget that a word can contain the character multiple times. I would follow an entire new direction.

my $word="cacao";
my @word=split ('',$word);
my @string=('_') x scalar @word;
my $char="c";
map { $string[$_] = $char if $word[$_] eq $char } 0..$#word;
print @string;

prints
c_c__

So, instead of working with strings, I would work with arrays. I even think this is faster than multiple substr lookups, but I am not sure.
---------------------------
Dr. Mark Ceulemans
Senior Consultant
IT Masters, Belgium

[UnderMine]

If you wish to replace all the charecters that you have not guessed with _ then :-

s/[^$guesses]/_/g;

Hope it helps
UnderMine

[tadman]

Another trick is to use index. A quick tour of the Perl functions will likely give you a whole bunch of ideas. It's worthwhile reading, since it will build your understanding of what tools you have at your disposal.