Re: Hash references and illegal octal digits

[Mr. Muskrat]

It's all in how you attempt to access the hash keys...
$hash{0109} results in the illegal octal digit warning but $hash{'0109'} does not. And the following works fine.

#!/usr/bin/perl
use strict;
use warnings;

my %hash = map { chomp; split /,/ } <DATA>;
for (sort keys %hash) { print "$_ => $hash{$_}",$/; }

__DATA__
1001,choochoo
1002,candycane
1003,sockpuppet
1004,choochoo
1005,candycane
1006,sockpuppet6
1007,foo
1008,bar
0001,choochoo
0002,candycane
0003,sockpuppet
0109,choochoo

Update: Doh! I forgot to tell you why! You see Perl treats all numbers that start with a 0 as octal (unless the 0 is followed by an x in which case it is treated as hexadecimal).

[peppiv]

Ah, yes. You is the genius!

Works great mon!

Supa Thanx,

and Happy Holidays!

peppiv

[peppiv]

Oops! One more breakdown. It appears the code

my %hash = map { chomp; split /,/ } @array;

doesn't play well with this data.



__DATA__
1001,choochoo
1002,candycane
1003,sockpuppet
1004,choochoo
1005,candycane
1006,sockpuppet6
1007,
1008,bar
0001,choochoo
0002,candycane
0003,sockpuppet
0109,choochoo


Where 1007 doesn't have any value. I have no idea how to treat this. Does anyone have any ideas?

peppiv

[I0]

my %hash = map { chomp; split /,/,$_,2 } @array;

[MarkM]

It is usually considered bad form to modify $_ during a map{} operation. People expect map{} to create a new list from an existing list, without modifying the existing list.

The expression can be written out clearer, more accurately, and using less intermediate memory by using the following code instead:

my %hash;
for (@array) {
    if (/^([^,]+)(?:,(.*))?$/) {
        $hash{$1} = $2;
    }
}

This also has the side effect of handling the case where the input takes the form "1009," or "1009". For "1009," the key will map to an empty string. For "1009" the key will map to the undefined value.

The regular expression removes the need for chomp() as the $ at the end of the regular expression will not swallow the "\n".

If efficiency is the true goal, the following code has the exact same effect:

my %hash;
/^([^,]+)(?:,(.*))?$/s && ($hash{$1} = $2) for @array;

If a few CPU ticks can be spared, the former is far more preferable to the latter.

[Mr. Muskrat]

Just ensure that there is something after the comma... even if it is a space.
If you have no control over the data then perhaps try something like this:
my %hash = map { s/,\n/, \n/; chomp; split /,/ } @array;