How do I recursively count file sizes in a script that works under both Windows and Linux?

[FiReWaLL]

$directory = '/thedir/thatiwantto/count';


print "\n\n";
print CountSize($directory);
print "\n\n";

sub CountSize {
    my ($directory) = $_[0];
    my ($ask, $filesize, $item, $size, @raiz);

    @raiz = glob("$directory/*.*") || warn();
    
    foreach $item (@raiz) {
        $ask = -d $item;
        if ($ask) {
            $size += &CountSize($item);
        } else {
            $size += -s $item;
        }
    }
    return($size);
}

It should return the total size of all the tree. In Windows, it works, but in Linux, it doesn't. It returns only the current directory file sizes. What should I do?

Originally posted as a Categorized Question.

[tachyon]

File::Find is part of the standard distro, reliable and portable.

use File::Find;

my $dir = 'c:/test';
my $size = 0;

find( \&size, $dir );

sub size {
   # we get each filename in $_
   my $file_size = -s $_;
   $size += $file_size;
   print "Found $_ $file_size Bytes\n";
}

print "$size Bytes in '$dir' and all subdirs\n";

[Crulx]

Here is a cross-platform way of doing it.

use strict;
my $dir = '.';
print &dir_tree_size($dir) . "\n";
exit 0;

sub dir_tree_size {
  my $dir = shift;
  my ($i,$total);
  $total = 0;
  opendir DIR, $dir;
  my @files = grep !/^\.\.?$/, readdir DIR;
  for $i (@files) {
    if(-d $i) { $total += dir_tree_size($dir . "/$i") }
    else { $total += -s $i}
  }
  return $total;
}

Crulx

[Anonymous Monk]

This always return 5333 on SuSE Linux 7.2 Kernel 2.4.4 Mark

[Anonymous Monk]

This doesnt seem to work recursively, just counts files in the current directory, not the subdirs.

[Anonymous Monk]

# crulx's solution has a bug - 
# readdir needs to have the directory glued back
# on once you're looking at files outside the 
# original directory

use strict;
my $dir = '.';
print &dir_tree_size($dir) . "\n";
exit 0;

sub dir_tree_size {
  my $dir = shift;
  my ($i,$total, $f);
  $total = 0;
  opendir DIR, $dir;
  my @files = grep !/^\.\.?$/, readdir DIR;
  for $i (@files) {
    $f = "$dir/$i";
    if(-d $f) { 
      $total += dir_tree_size($f) }
    else { 
      $total += -s $f}
  }
  return $total;
}