Re: randomly choosing elements from an array

[jdporter]

The canonical way to choose one element randomly from an array @a is

  $item = $a[ rand @a ];

If you need to do this n times, you could therefore do this:

  my @items;
  for ( 1 .. $n )
  {
    push @items, $a[ rand @a ];
  }

However, you have not said whether you can validly choose the same value twice. If not, then you'll have to remove each element from the set when you choose it. Like so:

  my @items;
  for ( 1 .. $n )
  {
    push @items, splice @a, rand @a, 1;
  }

Of course, if you'd prefer not to destroy @a, then work on a disposable copy of it.

jdporter
The 6th Rule of Perl Club is -- There is no Rule #6.

[grantm]

I recently had to solve the 'randomly select n unique elements from an array' problem. The solution I hit upon was to shuffle the list and take the first n elements. The trick being, you don't have to shuffle the whole list, you just need to ensure the first n elements were shuffled:

my @list = 'a'..'z';                                # use your data in
+stead of this
my $n = 5;                                          # how many do you 
+need?

foreach my $i (0..$n-1) {
  my $j = rand @list;
  ($list[$i], $list[$j]) = ($list[$j], $list[$i]);  # swap ith and jth
+ elements
};

print join(', ', @list[0..$n-1]), "\n";

As you say though, the original poster didn't specify whether unique selections were a requirement.

[merlyn]

Shuffling is still more work than you need to do if you can be destructive to the list. To pick $n items from list @list, use:

my @result;
push @result, splice @list, rand @list, 1 while @result < $n;

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

[sulfericacid]

Wow, this seems to be a lot easier than the method everyone else is aiming at. For the script I will actually require to only randomly call back unique instances of the phrase.

Thanks so much for your help!

"Age is nothing more than an inaccurate number bestowed upon us at birth as just another means for others to judge and classify us"

sulfericacid

[msh210]

This would seem to disallow duplicate choices:

my @items;
while (1) {
  my $item = $a[ rand @a ];
  push @items, $item unless $item ~~ @items;
  last if $n <= @items;
}