file tree to hash

[Anonymous Monk]

I have a directory tree that is being provided in the form of a flat text file.

/root/dir1/file1
/root/dir1/file2
/root/dir1/file3
/root/dir2/file1


What I would like to do is create a hash out of this information. (note: this file could be of any length and have a variable directory depth)
hash{root}{dir1}{file1} = $value (where $value is determined at run time)

My initial thought was to split each line into an array, and then use the information in node_id=196317 to turn the array into the hash. But this seems less than optimal.

What would be the best way to handle this problem?

[dakkar]

#!/usr/bin/perl -w
use Data::Dumper;

{my $i=1;
sub makevalue {
  return $i++;
}
}

my $hash={};my $h0;
my $l;my @c;
while ($l=<DATA>) {
  $h0=$hash;
  @c=split '/',$l;
  for my $c (@c[0..$#c-1]) {
    next unless $c;
    $h0=($h0->{$c}||={});
  }
  $h0->{$c[-1]}=makevalue($l);
}

print Dumper($hash);

__DATA__
/root/dir1/file1
/root/dir1/file2
/root/dir1/file3
/root/dir2/file1

Outputs:

$VAR1 = {
 'root' => {
   'dir2' => {
     'file1' => 4
    },
    'dir1' => {
      'file2' => 2,
      'file3' => 3,
      'file1' => 1
    }
  }
};

What does it do: it splits each row, and walks down the HoH (creating empty hashes as needed), putting the computed values (in this example just a counter) on the leaf.

I think this is more or less what you were describing, but I can't come up with a better solution.

-- 
        dakkar - Mobilis in mobile

[pg]

This is one way, less conventional:

use strict;
use Data::Dumper;

my %hash;
while (<DATA>) {
    chomp;
    s/\//}{/g;
    eval "\$hash".substr($_,1,length)."} = undef";
}
print Dumper(\%hash);

__DATA__
/root/dir1/file1
/root/dir1/file2
/root/dir1/file3
/root/dir2/file1

[merlyn]

And a huge security hole, as I published here a few years ago, in RE: RE: RE: "du" to hash.

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

[chromatic]

That's how I would do it. Why does it seem less than optimal? What do you mean by "best"?

[DrManhattan]

Here's another eval() solution.

#!/usr/bin/perl

use strict;
use Data::Dumper;

my %hash;
my $value = "determined at run time";
while (<DATA>)
{
    chomp;
    eval '$hash{'
        . join(
            "}{",
            split(/\//)
        )
        . "} = '$value'";
}

print Dumper(\%hash);

__DATA__
root/dir1/file1
root/dir1/file2
root/dir1/file3
root/dir2/file1

Edit: merlyn is correct. Don't ever use this. A file named "root/dir1/file1}=1;`someprogram`;$hash{foo" could be used to execute an external program.

-Matt

[merlyn]

Gah. Slow, and insecure. Gah. See RE: RE: RE: "du" to hash.

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.