How to remove elements from XML data?

[waxmop]

I need to delete some elements from an XML file, and I'm not sure how to do it intelligently.

I've got an XML file that looks sort of like this:

<opt>
  <node>
    <val>1</val>
  </node>
  <node>
    <val>2</val>
  </node>
  <node>
    <val>3</val>
  </node>
</opt>

And I want to remove some arbitrary node based on user input. Here's what I've got so far, assuming that I want to remove the node that has the "val" attribute set to 2:

use strict;
use XML::Simple;

my $xref = XMLin("<top><node><val>1</val></node><node><val>2</val></no
+de><node><val>3</val></node></top>");

my $nodenum = 0;
for my $n ( @{$xref->{'node'}} ) {
  if ( $n->{val} == 2 ) {
    splice @{$xref->{'node'}}, $nodenum, 1;
  }
  $nodenum++;
}

I really don't like using the $nodenum++ to track which element I'm iterating at, but I can't think of a better way.

[merlyn]

Another strategy:

use XML::LibXML;
my $d = XML::LibXML->new->parse_string(join "", <DATA>);
for my $dead ($d->findnodes(q{/opt/node[val = "2"]})) {
  $dead->unbindNode;
}
print $d->toString;

__END__
<opt>
  <node>
    <val>1</val>
  </node>
  <node>
    <val>2</val>
  </node>
  <node>
    <val>3</val>
  </node>
</opt>

which results in:

<?xml version="1.0"?>
<opt>
  <node>
    <val>1</val>
  </node>
  
  <node>
    <val>3</val>
  </node>
</opt>

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

[jasonk]

IMO, the grep route is the cleanest way:

$xref->{node} = [grep { $_->{val} != 2; } @{$xref->{node}}];

---

We're not surrounded, we're in a target-rich environment!

[Maxim]

I don't understand how you use this. $xref->{node} = [grep { $_->{val} != 2; } @{$xref->{node}}];
which module you are using??
Maxim