Re: Using an array in a hash

[btrott]

Your hash creation should look like this:

    %LdnLine = ($j => \@check2);

The value must be a reference, not an actual array.

To answer your second question--why does it look right when you print out the entire hash--that's because your array is being treated as a list to initialize the hash. It's not treated as an array value to your key $j; the values in @check2 are used as both keys and values in your hash. This is more clear if you do this:

    use Data::Dumper;
    print Dumper \%LdnLine;

With my dummy values for @check2 and $j this gave me

    $VAR1 = {
              1 => 'foo',
              'bar' => 'baz'
            };

Which, I'll bet, is not what you were expecting.

[maverick]

Just a bit of elaboration on an excellent post.

The keys and values in hashes can only be scalars, you can't directly store a array as a value. But, you can store a refrence to a array in a hash (a reference is a scalar) which is what btrott's code does.

When you want to make a reference to another variable use the \ operator.

my $ref_to_array  = \@an_array;
my $ref_to_hash   = \%a_hash;
my $ref_to_scalar = \$a_scalar;

Or if you don't want to make a variable and then make a reference, you can initialize them this way.

my $ref_to_array = [1,2,3,4];
my $ref_to_hash  = { 'key1' => 'val1', 'key2' => 'val2' };
my $ref_to_scalar = \"some string\n";

The contents can be retrieved like:

print $ref_to_array->[0];
print $ref_to_hash->{'some_key'};
print ${$ref_to_scalar};

All this stuff is explained in the o'reily (sp?) books in great detail. I'd suggest getting them. :)

/\/\averick

[tye]

The keys and values in hashes can only be scalars

And the keys can only be strings, not just any old scalar. A nit to pick, but an important one (which you probably already knew but that some readers may not have).

        - tye (but my friends call me "Tye")

[BlaisePascal]

To elaborate on that second part...

When you say %hash = (a => "foo", b => "bar") perl treats the "=>" operator as a synonym for ",", so this really looks like %hash = (a,"foo",b,"bar"). Perl knows to treat a list assigned to a hash as key/value pairs, so this works right.

In your example, where you tried %hash = (a => (foo,bar, baz)), perl treats the right hand side as (a,(foo,bar,baz)), which is "flattened" into (a,foo,bar,baz), which is then assigned to %hash, yielding %hash{a} = "foo" and %hash{bar} = "baz", which isn't what you wanted.

The suggestions to use references will do what you want.