Pattern Matching Problem

[Anonymous Monk]

I have a new perl problem, that I haven't quite figured out the Regular Expression for. We have a web based form that submits data in paragraph form with variables from the form entered into it. A typical set of data may look like this.

Patron @FirstName@ @LastName@ has filled out the @FormName@ form. Plea
+se send them an email at @EmailAddress@.

Where FirstName, LastName, FormName, and EmailAddress are the actual values, not the variable names. What I need to do, is highlight each of those variables by placing a <B> after the first "@" and a </B> before the second "@", in each one of those variables (without removing the "@"). Best I can come up with is going through the string one character at a time, and watching which "@" I am on. There has got to be a better way to perform this. Iterating over the whole string like that seems sloppy.

[Abigail-II]

    s!\@([^\@]*)\@!\@<B>$1</B>\@!g;

Abigail

[allolex]

Ok, so this one catches a string of any length (including zero), using *. The string can be any character except "@" [^\@]. The matching expression on the left captures the non-@ string and puts it into the variable $1, which is then put between bold tags. Abigail-II has used exclamation points here to improve legibility.

--
Allolex

[allolex]

#!/usr/bin/perl
$_ = 'Patron @FirstName@ @LastName@ has filled out the @FormName@ form
+. Please send them an email at @EmailAddress@.';

s/@([a-zA-Z]+?)@/<b>\@$1\@<\/b>/g;

print $_ . "\n";
# Output: Patron <b>@FirstName@</b> <b>@LastName@</b> has filled out t
+he <b>@FormName@</b> form. Please send them an email at <b>@EmailAddr
+ess@</b>.

This gets the right output with the sample data you gave. I hope it helps you along.

--
Allolex

Update 2003-08-06 15:28:15 CEST: Fixed substitution problem pointed out by Abigail-II (Thanks!).

[Abigail-II]

That removes the @ signs, of which the OP explicitely mentions they shouldn't be removed.

Abigail

[ph0enix]

my $text = 'Patron @FirstName@ @LastName@ has filled out the @FormName
+@ form. Please send them an email at EmailAddress@.';
my $c=0;
$text =~ s/\@([^\@]+)/$c++;($c%2)?"\@<b>$1<\/b>":"\@$1"/eg;

[monktim]

Here you go.

use strict;
use warnings;

my $str = 'Patron @FirstName@ @LastName@ has filled out the @FormName@
+ form. Please send them an email at @EmailAddress@.';
print "$str\n";
$str =~ s/\@(.*?)\@/\@<B>$1<\/B>\@/g;
print "$str\n";

[eric256]

Seemed like a good spot for look behind and lookahead :-)

my $test = 'Patron @FirstName@ @LastName@ has filled out the @FormName
+@ form. Please send them an email at 

@EmailAddress@.';

$test =~ s/(?<=@)        # starts with @ (but don't grab @)
       ([a-zA-Z]*)        # string of letters
           (?=@)        # ends with @ (but don't grab @)
      /<b>$1<\/b>/xg;    # put $1 back with bold tags around it. @ are
+ preserved.

print $test;

___________
Eric Hodges