SSL certificate generator

[IlyaM]

I routinely create self subscribed SSL certs for testing purposes. So I wrote this script to automate this process:

#!/usr/bin/perl

use strict;
use warnings;

use IPC::Run qw(start run);

my $hostname = shift @ARGV;
die "Usage: make_cert HOSTNAME" unless defined $hostname;

{
    print "CREATE THE KEY AND REQUEST:\n\n";

    my @cmd = qw(openssl req -new -keyout temp.pem -out temp.csr);
    my @io = ('Enter PEM pass phrase:',
              'test',
              'Verifying password - Enter PEM pass phrase:',
              'test',
              'Country Name.*:',
              'UK',
              'State.*:',
              'Warwickshire',
              'Locality Name.*:',
              'Kenilworth',
              'Organization Name.*:',
              'Iponweb Ltd',
              'Organizational Unit Name.*:',
              '',
              'Common Name.*:',
              $hostname,
              'Email Address.*',
              '',
              'A challenge password.*:',
              '',
              'An optional company name.*:',
              '');

    expect(cmd => \@cmd, io => \@io);
    print "\n";
}

{
    print "REMOVE THE PASSPHRASE FROM THE KEY:\n\n";

    my @cmd = qw(openssl rsa -in temp.pem -out temp.key);
    my @io = ('Enter PEM pass phrase:',
              'test');

    expect(cmd => \@cmd, io => \@io);
    print "\n";
}

{
    print "CREATE THE KEY AND REQUEST:\n\n";

    my @cmd = qw(openssl x509 -in temp.csr -out temp.cert -req -signke
+y temp.key -days 365);
    my @io = ();

    expect(cmd => \@cmd, io => \@io);
    print "\n";
}

{
    print "PREPARING FILES:\n\n";

    unlink 'temp.csr';
    my $cert = $hostname . '.cert';
    rename 'temp.cert', $cert;
    my $key = $hostname . '.key';
    rename 'temp.key', $key;

    print "$cert and $key are ready for usage\n\n";
}

sub expect {
    my %param = @_;

    my @io = @{$param{io}};

    my $out;
    my $in;

    my $h = start($param{cmd}, '<pty<', \$in, '>pty>', \$out);

    my $last_length = 0;
    while(1) {
        my $expected = shift @io;
        last unless defined $expected;
        my $input    = shift @io;
        last unless defined $input;

        until($out =~ /\G.*$expected/sgc) {
            $h->pump;
            local $| = 1;
            print substr $out, $last_length;
            $last_length = length $out;
        }

        $in .= $input . "\n";
    }

    $h->finish;
    print substr $out, $last_length;
}

--
Ilya Martynov, [e-mail]
CTO IPonWEB (UK) Ltd
Quality Perl Programming and Unix Support UK managed @ offshore prices - http://www.iponweb.net
Personal website - http://martynov.org