Elegant (i.e. declarative) way to find all possibly overlapping matches

[jsegal]

Howdy.
The "canonical" way to find all matches in a string is with m//g. For example, to find the starting positions of a substring "abc" in a string you could do:

while ($s =~ /abc/g) {
   print "found abc at $-[0]\n";
}

Now suppose the pattern we are looking for overlaps with itself -- e.g. is aa. The following:

while ($s =~ /aa/g) {
   print "found aa at $-[0]\n";
}

does not quite work: if the input string is "baaaad", for example, it would output:

  found aa at 1
  found aa at 3

It leaves out "found aa at 2", which is entirely expected given how /g is defined (the next match starts after the end of the previous one).

Now, it is straightforward enough to tweak the loop so it finds all the matches, using pos as an lvalue:

while ($s =~ /aa/g) {
   print "found aa at $-[0]\n";
   pos($s) = $-[0] + 1;
}

This "tricks" the RE engine to start searching again at the very next character, so all matches will be found, even if they overlap.

This works fine, and solves the particular practical problem I am working on, but it got me to thinking: is it possible to get this bevahior purely declaratively -- i.e. in the RE itself, not by tweaking pos after the match?

Thanks!

Update:Just as I was about to post this, I figured out my own answer, using a lookahead: /(?=aa)./. The lookahead matches without advancing pos, the "." advances pos by 1. Are there other ways to do this? More efficient ways?

--JAS

[tye]

Update: Just as I was about to post this, I figured out my own answer, using a lookahead: /(?=aa)./. The lookahead matches without advancing pos, the "." advances pos by 1. Are there other ways to do this? More efficient ways?

You don't need the dot:

    my $str= "aaa aa aaa";
    print "String = '$str'\n";
    while(  $str =~ /(?=aa)/g  ) {
        print pos($str), $/;
    }
__END__
String = 'aaa aa aaa'
0
1
4
7
8

See RE: Re: ^x* vs x*$ for why.

                - tye ("Twice in one day")

[Zaxo]

As long as you're looking for literal strings instead of regex matches,

my $spot = 0;
while (($spot = index $s, 'aa', $spot) != -1) {
    printf "found aa at %d\n", $spot++;
}

The increment in the loop is important.

After Compline,
Zaxo

[Not_a_Number]

Not particularly elegant, I suppose, but Another Way To Do It (using substr):

my $str = 'braaaafdhjklghaa';
my $sstr = 'aa';
my $len = length $sstr;
for ( 0 .. ( length $str ) - $len ) {
   print "Found at $_\n" if substr ($str, $_, $len) eq $sstr;
}

dave

[flounder99]

Why bother with the while loop?

my $str= "aaa aa aaa";
print "String = '$str'\n";
() = $str =~ /(?=aa)(?{print pos($str),"\n"})./g;
__END__
String = 'aaa aa aaa'
0
1
4
7
8

--

flounder

[bsb]

FYI, This is in Japhy's book. Along with a lot of other good stuff. http://japhy.perlmonk.org/book/