Backtracking problem with .*(?!bar)

[olivierp]

I have a file containing records separated by a |.
In order to classify these entries, I first split each line, and match certain fields against a hash of filters.

The filters are loaded from a configuration file at run-time.
I am thus limited to $var[5] =~ /$regex/ (or at least I think so) for my matching.
Is it possible to get something like this to work:

$re[0] = qr (.*(?!system))i;
$re[1] = qr (system)i;
$v[0] = "oneitem";
$v[1] = "anothersystem";

for $a (@v) {
  for $r (@re) {
    print "\nRegex: $r\tValue: $a\n";
    if ($a =~ /$r/) {
      print "$a matches $r\n" ;
    }
  }
}

As this results in:

Regex: (?-xism:.*(?!system))    Value: oneitem
oneitem matches (?-xism:.*(?!system))

Regex: (?-xism:system)  Value: oneitem

Regex: (?-xism:.*(?!system))    Value: anothersystem
anothersystem matches (?-xism:.*(?!system))

Regex: (?-xism:system)  Value: anothersystem
anothersystem matches (?-xism:system)

Which is not what I want...
Is it possible to construct a regex that "matches if doesn't contain" ?

[Abigail-II]

Is it possible to construct a regex that "matches if doesn't contain" ?

Most certainly:

    /^(?:(?!system).)*$/

Abigail

[BrowserUk]

Or somewhat more efficiently,

print "Doesn't contain 'system'" 
    if $string =~ m[^(?!.*system)];

---

Examine what is said, not who speaks.
"Efficiency is intelligent laziness." -David Dunham
"When I'm working on a problem, I never think about beauty. I think only how to solve the problem. But when I have finished, if the solution is not beautiful, I know it is wrong." -Richard Buckminster Fuller
If I understand your problem, I can solve it! Of course, the same can be said for you.

[olivierp]

Many thanks to both of you !
This had me flummoxed for quite some time.

For my understanding:
Abigail's answer reads
Beginning of line, followed any number of times by anything that isn't preceded by "system",
follwed by an end of line marker

and BrowserUK's reads:
Beginning of line not followed by anything that is followed by "system"


In both cases, I assume that it is the presence of begin/end line qualifiers that stops the regex
from backtracking and matching any as .*(?!system) does.
Shame an Initiate can't at least cast one vote :(

[merlyn]

In both cases, I assume that it is the presence of begin/end line qualifiers that stops the regex from backtracking and matching any as .*(?!system) does.

No, they ask for different things. It's not the anchor that is helping.

The regex /^.*(?!system)/ says "does there exist some number of characters which is not immediately followed by 'system'?". And yes, there are many such solutions in strings such as "infosystem". The letter "i" is not followed by system. The letters "in" are not followed by system. The letters "inf" are not followed by system, and so on.

However, /^(?!.*system)/ says "starting from the beginning of the string, do I fail to match any sequence of characters followed by 'system'?". So, if the inner match fails, the outer match succeeds, and that's exactly what we want. Not that without the anchor, the outer start point could move all the way past the "s" in system, and then the inner match would fail causing the outer match to succeed. So the anchor is still needed.

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

[vbrtrmn]

I have found people don't like to use the .*, I try to use it as infrequently as possible. Maybe one of these would help you out

.{0,} - Match 0 or more times.
.??   - Match 0 or 1 times (as few as possible).

--
paul

[perlguy]

Could I get an example from you on when using the ?? quantifier would be appropriate? I find this a strange example to show as an alternative to the infamous dot star.

[merlyn]

Uh, what do you think .{0,} does that .* doesn't, or vice versa?

They are absolutely in every way identical.

-- Randal L. Schwartz, Perl hacker
Be sure to read my standard disclaimer if this is a reply.

[tsee]

Except that .* is better for golf!